Shader 标准贴图代码参考笔记

// Upgrade NOTE: replaced 'mul(UNITY_MATRIX_MVP,*)' with 'UnityObjectToClipPos(*)'

Shader "wacky/s6 wac" {
    Properties{
    _Diffuse("Diffuse Color",color)=(1,1,1,1)
    _Specular("Specular",Color) = (1,1,1,1)
    _Gloss("Gloss",Range(10,200)) = 20
    }
    SubShader{
        Pass{
                Tags {"LightMode" = "ForwardBase"}
                CGPROGRAM
                #include "Lighting.cginc"
                #pragma vertex vert
                #pragma fragment frag
                fixed4 _Diffuse;
                fixed4 _Specular;
                half _Gloss;

                struct a2v{
                    float4 vertex:POSITION;
                    float3 normal:NORMAL;
                };

                struct v2f{
                    float4 svPos:SV_POSITION;
                    float3 worldNormal:TEXCOORD0;
                    float4 worldVertex:TEXCOORD1;
                };

                v2f vert(a2v v){
                    v2f f;
                    f.svPos = UnityObjectToClipPos(v.vertex); //剪裁空间顶点信息 = 求乘(矩阵,模型顶点信息)
                    f.worldNormal = UnityObjectToWorldNormal(v.normal); //世界空间法线信息 = UnityObjectToWorldNormal   unity模型转世界空间法线(模型法线)
                    f.worldVertex = mul(unity_ObjectToWorld,v.vertex); //世界空间顶点信息 = 求乘(unity_ObjectToWorld,模型顶点信息)
                    return f;
                }

                fixed4 frag(v2f f):SV_Target{
                    fixed3 normalDir = normalize(f.worldNormal); 
                    //法线方向 = 单位化(世界空间法线);

                    fixed3 lightDir = normalize(WorldSpaceLightDir(f.worldVertex)); 
                    //光照方向 = 单位化(WorldSpaceLightDir世界空间灯光方向(世界顶点信息));

                    fixed3 diffuse = _LightColor0.rgb * _Diffuse.rgb * max(dot(normalDir,lightDir),0); 
                    //漫反射 = 第一个光照颜色 * 漫反射颜色 * 取大(dot点积(法线方向,光照方向),0) //dot点积的作用是用来运算反射的角度

                    fixed3 viewDir = normalize(UnityWorldSpaceViewDir(f.worldVertex));
                     //相机方向 = 单位化(UnityWorldSpaceViewDir  unity世界空间视眼方向(世界空间顶点信息));

                    fixed3 halfDir = normalize(lightDir + viewDir); 
                    //半角方向 = 单位化(光照方向 + 视眼方向)

                    fixed3 specular = _LightColor0.rgb * _Specular.rgb * pow(max(dot(normalDir,halfDir),0),_Gloss); 
                    //高光反射 = 第一个光照颜色 * 高光颜色 * pow(取大(点积(法线方向,半角方向),0保证纯暗部不反射), 高光范围大小)   //pow(x,y) x的y次方 由于x小于1，所以y越大，x越小

                    fixed3 tempColor = diffuse + specular + UNITY_LIGHTMODEL_AMBIENT.rgb; 
                    //物色颜色 = 漫反射 + 高光颜色 + 环境光 (UNITY_LIGHTMODE_AMBIENT)

                    return fixed4(tempColor,1);

                }

                ENDCG
            }
    }
    Fallback "Diffuse"
}