Unity内置渲染管线升级URP及兼容SRP Batcher

参考文档：

URP官方文档：https://docs.unity3d.com/Packages/com.unity.render-pipelines.universal@7.3/manual/index.html

HLSL官方文档：https://docs.microsoft.com/en-us/windows/win32/direct3dhlsl/dx-graphics-hlsl

Built-in和URP中光照的区别 https://blog.csdn.net/enk_2/article/details/106376694

https://teodutra.com/unity/shaders/urp/graphics/2020/05/18/From-Built-in-to-URP/

http://blog.coolcoding.cn/?p=2313

https://acgmart.com/render/urp-shaderlibrary/

https://cyangamedev.wordpress.com/2020/06/05/urp-shader-code/

https://zhuanlan.zhihu.com/p/336428407

https://www.cnblogs.com/Jaysonhome/p/12900808.html

关键点记录：

0.未使用光照计算的shader升级后不做修改仍然可以使用，但是可能会不兼容SRP Batcher，所以仍然需要修改，使用了光照计算的shader必须要修改。

1.SubShader的Tags中增加 "RenderPipeline"="UniversalPipeline"声明

2.每个Pass的Tags中指定 "LightMode"=使用的光照模式，URP使用一个单pass前向渲染器，所以只有第一个"LightMode"="UniversalForward"的Pass（GPU支持的）被用于渲染物体。

3.为了让着色器和SRP Batcher兼容，所有的Pass必须共享相同的 UnityPerMaterial CBUFFER，如果调用 UsePass 使用的Pass不匹配就会出问题（至少在当前URP版本中是这样，未来获取会修复这个问题）

4.CG和HLSL都可以使用，但是CG已经很多年不维护了。CGPROGRAM/CGINCLUDE 和 ENDCG这些tags会自动包含一些内置头文件，比如HLSLSupport.cginc 和 UnityShaderVariables.cginc.如果在URP中使用CG Tags会出现一些变量和函数与 URP ShaderLibrary冲突，导致重定义。URP应该替换使用 HLSLPROGRAM/HLSLINCLUDE 和 ENDHLSL。这些tags不会引用上面提到的头文件。

5.在SubShader中的每个Pass使用HLSLINCLUDE包含代码并不是必须的，但是很有用，可以确保 UnityPerMaterial CBUFFER在每个Pass都相同，这是使得Shader兼容 SRP Batcher所要求的。这个 CBUFFER 需要包含所有暴露出来的属性，不能包含没有暴露出来的变量，也不需要包含textures。

HLSLINCLUDE
    #include "Packages/com.unity.render-pipelines.universal/ShaderLibrary/Core.hlsl"
 
    CBUFFER_START(UnityPerMaterial)
    float4 _BaseMap_ST;
    float4 _BaseColor;
    //float4 _ExampleDir;
    //float _ExampleFloat;
    CBUFFER_END
ENDHLSL

使用URP ShaderLibrary引用 Core.hlsl替换内置渲染管线中的UnityCG.cginc，二者等价。

6.在URP中纹理和采样器的定义改成如下写法：

TEXTURE2D(_BaseMap);
SAMPLER(sampler_BaseMap);

7.使用 TransformObjectToHClip（在pipeline-core SpaceTransforms.hlsl头文件中） 替换 UnityObjectToClipPos 或者改成如下写法：

Varyings vert(Attributes IN) {
    Varyings OUT;
 
    VertexPositionInputs positionInputs = GetVertexPositionInputs(IN.positionOS.xyz);
    OUT.positionCS = positionInputs.positionCS;
    // Or this :
    //OUT.positionCS = TransformObjectToHClip(IN.positionOS.xyz);
 
    OUT.uv = TRANSFORM_TEX(IN.uv, _BaseMap);
    OUT.color = IN.color;
    return OUT;
}

GetVertexPositionInputs 计算不同坐标系中的位置，结果包含世界坐标系坐标，观察坐标系坐标，裁剪坐标系坐标，标准设备坐标系坐标，未使用到的坐标不会被包含到编译出的shader中，所以不会有额外的不必要的计算量。TRANSFORM_TEX 在内置渲染管线和URP中都可以用。GetVertexNormalInputs 可以将法线和切线从对象坐标系变换到世界坐标系。也可以用 TransformObjectToWorldNormal(IN.normalOS) 代替。

VertexNormalInputs normalInputs = GetVertexNormalInputs(IN.normalOS, IN.tangentOS);

8.使用URP ShaderLibrary中的 SAMPLE_TEXTURE2D 宏采样纹理。

half4 frag(Varyings IN) : SV_Target {
    half4 baseMap = SAMPLE_TEXTURE2D(_BaseMap, sampler_BaseMap, IN.uv);
    return baseMap * _BaseColor * IN.color;
}

9.区分 multi_compile 和 shader_feature，剥离不需要的编译选项，减少shader变体。

https://zhuanlan.zhihu.com/p/77043332

https://www.jianshu.com/p/8750704a2f4c

10.URP不支持表面着色器，URP ShaderLibrary 中处理光照计算的函数在 Lighting.hlsl中，该文件需要手动include。

//这些编译指令用于接收阴影
#pragma multi_compile _ _MAIN_LIGHT_SHADOWS
#pragma multi_compile _ _MAIN_LIGHT_SHADOWS_CASCADE
#pragma multi_compile _ _SHADOWS_SOFT
 
#include "Packages/com.unity.render-pipelines.universal/ShaderLibrary/Lighting.hlsl"

11.当使用Lighting.hlsl支持光照和阴影，应该添加下面的编译选项，如果没有定义，ShaderLibrary会跳过一些计算。

// Main Light Shadows
#pragma multi_compile _ _MAIN_LIGHT_SHADOWS
#pragma multi_compile _ _MAIN_LIGHT_SHADOWS_CASCADE
 
// Additional Lights & Shadows
#pragma multi_compile _ _ADDITIONAL_LIGHTS_VERTEX _ADDITIONAL_LIGHTS
#pragma multi_compile _ _ADDITIONAL_LIGHT_SHADOWS
 
// Soft Shadows
#pragma multi_compile _ _SHADOWS_SOFT
 
// Other (Mixed lighting, baked lightmaps, fog)
#pragma multi_compile _ _MIXED_LIGHTING_SUBTRACTIVE
#pragma multi_compile _ DIRLIGHTMAP_COMBINED
#pragma multi_compile _ LIGHTMAP_ON
#pragma multi_compile_fog
 
// Supporting shadows will also require passing a positionWS, 
// and shadowCoord into the fragment shader, again you'll have 
// to see the Lighting sections for actual examples.

12.为了处理雾，使用ComputeFogFactor 和 MixFog 函数。

#pragma multi_compile_fog
 
struct Varyings {
    ...
    half fogFactor : TEXCOORD5;
    // or whatever unused texcoord
    // if none are unused pack it together with a half3 or something
}
...
 
// In the vertex shader :
half fogFactor = ComputeFogFactor(positionInputs.positionCS.z);
 
// In the fragment, just before returning the color :
color.rgb = MixFog(color.rgb, IN.fogFactor);

兼容SRP Batcher要点：

1.渲染对象必须是 mesh 或者 skinned mesh，不支持粒子。

2.自定义的shader必须兼容 SRP Batcher，自带的Lit和Unlit支持。

3.渲染的对象不能使用 MaterialPropertyBlocks。

4.引擎的内置shader属性必须放在一个名为UnityPerDraw的CBUFFER中. 比如： unity_ObjectToWorld, unity_SHAr

5.自定义shader属性必须放在名为UnityPerMaterial 的CBUFFER中。