UnityShader初级篇——遮罩纹理

1.遮罩纹理可以保护某些区域，使其免受修改

Shader"Unity Shaders Book/Chapter 7/Mask Texture"
{
	Properties
	{
		_Color ("Color Tint", Color) = (1,1,1,1)
		_MainTex("Main Tex", 2D) = "white" {}
		_BumpMap ("Normal Map", 2D) = "bump"{}
		_BumpScale("Bump Scale", Float) =1.0
		//高光反射遮罩纹理
		_SpecularMask("Specular Mask", 2D) = "white"{}
		//控制遮罩影响度
		_SpecularScale("Specular Scale", Float) = 1.0 
		_Specular ("Specular", Color) = (1,1,1,1)
		_Gloss ("Gloss", Range(8.0, 256)) = 20 
	}
	SubShader
	{
		Pass
		{
		        Tags{"LightMode" = "ForwardBase"}
                        
			CGPROGRAM
			#pragma vertex vert
			#pragma fragment frag

			#include "LIghting.cginc"

			fixed4 _Color;
			sampler2D _MainTex;
			//主纹理、法线纹理、遮罩纹理共同使用此纹理属性，修改主纹理系数会同时影响3个纹理的采样
			float4 _MainTex_ST;
			sampler2D _BumpMap;
			float _BumpScale;
			sampler2D _SpecularMask;
			float _SpecularScale;
			fixed4 _Specular;
			float _Gloss;

			struct a2v
			{
				float4 vertex : POSITION;
				float3 normal : NORMAL;
				float4 tangent : TANGENT;
				float4 texcoord : TEXCOORD0;
			};

			struct v2f
			{
			        float4 pos : SV_POSITION;
			        float2 uv : TEXCOORD0;
			        float3 lightDir : TEXCOORD1;
			        float3 viewDir : TEXCOORD2;
			};		

			//将光照方向和视角方向从模型空间转换到切线空间
			v2f vert (a2v v)
			{
				v2f o;
				o.pos = UnityObjectToClipPos(v.vertex);
				//使用内置宏TRANSFORM_TEX(顶点纹理坐标，纹理名)计算经过平铺和偏移后的纹理坐标
				o.uv = TRANSFORM_TEX(v.texcoord, _MainTex);

				TANGENT_SPACE_ROTATION;
				o.lightDir = mul(rotation, ObjSpaceLightDir(v.vertex)).xyz;
				o.viewDir = mul(rotation, ObjSpaceViewDir(v.vertex)).xyz;
				return o;
			}

			//在片元着色器中使用遮罩纹理控制模型表面的高光反射强度
			fixed4 frag (v2f i) : SV_Target
			{
				fixed3 tangentLightDir = normalize(i.lightDir);
				fixed3 tangentViewDir = normalize(i.viewDir);

				fixed3 tangentNormal = UnpackNormal(tex2D(_BumpMap, i.uv));
				tangentNormal.xy *= _BumpScale;
				tangentNormal.z = sqrt(1.0 - saturate(dot(tangentNormal.xy, tangentNormal.xy)));

				//纹理贴图
				fixed3 albedo = tex2D(_MainTex, i.uv).rgb * _Color.rgb;
				//环境光
				fixed3 ambient = UNITY_LIGHTMODEL_AMBIENT.xyz * albedo;
				//漫反射
				fixed3 diffuse = _LightColor0.rgb * albedo * max(0, dot(tangentNormal,tangentLightDir));
				//Blinn-Phong光照
				fixed3 halfDir = normalize(tangentLightDir + tangentViewDir);

				//获取遮罩数据
				fixed specularMask = tex2D(_SpecularMask, i.uv).r * _SpecularScale;
				//添加高光遮罩计算高光
				fixed3 specular = _LightColor0.rgb * _Specular.rgb * pow(max(0,dot(tangentNormal,halfDir)), _Gloss) * specularMask;

				return fixed4(ambient + diffuse + specular,1.0);

;			}
			ENDCG
		}
	}

	Fallback"Specular"
}