shader篇-纹理-遮罩纹理

shader篇-纹理-遮罩纹理

---

简介

==

什么是遮罩纹理？它保护了某些区域，使他们免于某些修改。
比如说高光，你希望模型不同区域有不同的高光强度和高光指数，从而达成细腻的效果，就可以用遮罩纹理控制光照。
比如制作地形需要混混多张图片，遮罩纹理可以控制如何混合这些纹理。

使用流程和原理

遮罩纹理的使用流程是：采用得到遮罩纹理的纹素值后，使用其中某个通道值与表面属性相乘。这样，当通道为0时，可以保护表面属性不受该属性的影响。

代码实现

配置

Properties {
        _Color ("Color Tint", Color) = (1, 1, 1, 1)
        _MainTex ("Main Tex", 2D) = "white" {}
        _BumpMap ("Normal Map", 2D) = "bump" {}
        _BumpScale("Bump Scale", Float) = 1.0

        //高光反射遮罩纹理
        _SpecularMask ("Specular Mask", 2D) = "white" {}
        //控制遮罩影响度的系数
        _SpecularScale ("Specular Scale", Float) = 1.0

        _Specular ("Specular", Color) = (1, 1, 1, 1)
        _Gloss ("Gloss", Range(8.0, 256)) = 20
    }
    SubShader {
        Pass { 
            Tags { "LightMode"="ForwardBase" }

            CGPROGRAM

            #pragma vertex vert
            #pragma fragment frag

            #include "Lighting.cginc"

            fixed4 _Color;
            sampler2D _MainTex;
            float4 _MainTex_ST;
            sampler2D _BumpMap;
            float _BumpScale;
            sampler2D _SpecularMask;
            float _SpecularScale;
            fixed4 _Specular;
            float _Gloss;

输入输出结构体

struct a2v {
    float4 vertex : POSITION;
    float3 normal : NORMAL;
    float4 tangent : TANGENT;
    float4 texcoord : TEXCOORD0;
};

struct v2f {
    float4 pos : SV_POSITION;
    float2 uv : TEXCOORD0;
    float3 lightDir: TEXCOORD1;
    float3 viewDir : TEXCOORD2;
    };

顶点着色器
在顶点着色器完成了坐标的变换，把它们从模型空间变换到了切线空间

v2f vert(a2v v) {
    v2f o;
    o.pos = UnityObjectToClipPos(v.vertex);

    o.uv.xy = v.texcoord.xy * _MainTex_ST.xy + _MainTex_ST.zw;

    TANGENT_SPACE_ROTATION;
    o.lightDir = mul(rotation, ObjSpaceLightDir(v.vertex)).xyz;
    o.viewDir = mul(rotation, ObjSpaceViewDir(v.vertex)).xyz;

    return o;
    }

片元着色器
我们在片元着色器使用遮罩纹理

fixed4 frag(v2f i) : SV_Target {
    fixed3 tangentLightDir = normalize(i.lightDir);
    fixed3 tangentViewDir = normalize(i.viewDir);

    fixed3 tangentNormal = UnpackNormal(tex2D(_BumpMap, i.uv));
    tangentNormal.xy *= _BumpScale;
    tangentNormal.z = sqrt(1.0 - saturate(dot(tangentNormal.xy, tangentNormal.xy)));

    fixed3 albedo = tex2D(_MainTex, i.uv).rgb * _Color.rgb;

    fixed3 ambient = UNITY_LIGHTMODEL_AMBIENT.xyz * albedo;

    fixed3 diffuse = _LightColor0.rgb * albedo * max(0, dot(tangentNormal, tangentLightDir));

    fixed3 halfDir = normalize(tangentLightDir + tangentViewDir);

    //在计算高光反射，采用遮罩纹理来控制高光强度
    fixed specularMask = tex2D(_SpecularMask, i.uv).r * _SpecularScale;

    fixed3 specular = _LightColor0.rgb * _Specular.rgb * pow(max(0, dot(tangentNormal, halfDir)), _Gloss) * specularMask;

    return fixed4(ambient + diffuse + specular, 1.0);
}

遮罩纹理除了用来保护某些区域使它们免于修改，还可以存储其他逐像素控制的表面属性。