Unity Shader 遮罩纹理

 遮罩允许我们可以保护某些区域，使它们免于某些修改。

 

得到更加细腻的效果。

一些材质需要混合多张图片，遮罩纹理可以控制如何混合这些纹理。

 

使用遮罩纹理的流程一般是：通过采样得到遮罩纹理的纹素值，然后使用其中某个（或某几个）通道的值

（例如 texel.r ----- R通道的值）来与某种表面属性进行相乘，这样当该通道的值为0时，可以保护表面不受该属性的影响。

 

下例，一张高光遮罩纹理，逐像素地控制模型表面的高光反射强度。

Shader "MyShader/MaskTexture"
{
    Properties
    {
        _Color("Color Tint",Color) = (1,1,1,1)
        _MainTex("Main Tex",2D) = "white"{}
        _BumpMap("Normal Map",2D) = "bump"{}
        _BumpScale("Bump Scale",Float) = 1.0
        _SpecularMask("Specular Mask",2D) = "white"{}
        _SpecularScale("Specular Scale",Float) = 1.0
        _Specular("Specular",Color) = (1,1,1,1)
        _Gloss("Gloss",Range(8.0,256)) = 20
    }

        SubShader
        {
            Pass
        {
            Tags{"LightMode" = "ForwardBase"}

            CGPROGRAM
#pragma vertex vert
#pragma fragment frag
#include "Lighting.cginc"

            fixed4 _Color;
        sampler2D _MainTex;
        float4 _MainTex_ST;
        sampler2D _BumpMap;
        float _BumpScale;
        sampler2D _SpecularMask;
        float _SpecularScale;
        fixed4 _Specular;
        float _Gloss;

        struct a2v
        {
            float4 vertex:POSITION;
            float3 normal:NORMAL;
            float4 tangent:TANGENT;
            float4 texcoord:TEXCOORD0;
        };

        struct v2f
        {
            float4 pos:SV_POSITION;
            float2 uv:TEXCOORD0;
            float3 lightDir:TEXCOORD1;
            float3 viewDir:TEXCOORD2;
        };

        v2f vert(a2v v)
        {
            v2f o;

            o.pos = UnityObjectToClipPos(v.vertex);

            o.uv.xy = v.texcoord.xy * _MainTex_ST.xy + _MainTex_ST.zw;

            TANGENT_SPACE_ROTATION;

            o.lightDir = mul(rotation, ObjSpaceLightDir(v.vertex)).xyz;

            o.viewDir = mul(rotation, ObjSpaceViewDir(v.vertex)).xyz;

            return o;
        }

        fixed4 frag(v2f i):SV_Target
        {
            fixed3 tangentLightDir = normalize(i.lightDir);

        fixed3 tangentViewDir = normalize(i.viewDir);

        fixed3 tangentNormal = UnpackNormal(tex2D(_BumpMap, i.uv));
        tangentNormal.xy *= _BumpScale;
        tangentNormal.z = sqrt(1.0 - saturate(dot(tangentNormal.xy, tangentNormal.xy)));

        fixed3 albedo = tex2D(_MainTex, i.uv).rgb * _Color.rgb;

        fixed3 ambient = UNITY_LIGHTMODEL_AMBIENT.xyz * albedo;

        fixed3 diffuse = _LightColor0.rgb * albedo * max(0, dot(tangentNormal, tangentLightDir));

        fixed3 halfDir = normalize(tangentViewDir + tangentLightDir);

        fixed3 specularMask = tex2D(_SpecularMask, i.uv).r * _SpecularScale;

        fixed3 specular = _LightColor0.rgb * _Specular.rgb * pow(max(0, dot(tangentNormal, halfDir)), _Gloss) * specularMask;

        return fixed4(ambient + diffuse + specular, 1.0);

        }
            ENDCG
        }
        }

            Fallback "Specular"
}

 我们为主纹理 _MainTex 法线纹理 _BumpMap 和遮罩纹理 _SpecularMask 定义了它们共同使用的纹理属性变量 _MainTex_ST。

意味着修改主纹理的平铺系数和偏移系数会同时影响3个纹理的采样。

这样让我们节省存储纹理坐标数目。

很多时候，我们不需要对纹理进行平铺和偏移操作，或者很多纹理可以使用用一种平铺和偏移操作。

 

本例，使用的遮罩纹理中每个纹素的rgb分量其实是一样的，这里选择用 r 分量来计算

我们往往会充分利用遮罩纹理中的每一个颜色通道来存储不同的表面属性。

效果

 遮罩纹理可以存储任何我们希望逐像素控制的表面属性。例如，一张纹理的RGBA四个通道，我们可以把高光反射的强度存储在R通道，把边缘光照的强度存储在G通道，把高光反射的指数部分存储在B通道，把自发光强度存储在A通道。

游戏DOTA2 中每个模型使用4张纹理：一张用于定义模型颜色，一张用于定义表面法线，另外两张都是遮罩纹理。这样两张遮罩纹理提供共8种额外的表面属性。使得人物材质自由度很强，可以支持很多高级的模型属性。

参考 我买的 unity shader 入门精要