【UnityShader】遮罩纹理

基础知识

• 遮罩运行我们可以保护某些区域，使它们免于某些修改。

• 常见使用

  1. 在之前的实现中，我们都是把高光反射应用到模型表面的所有地方，即所有的像素都使用同样大小的高光强度和高光指数。但有时，我们希望模型表面某些区域的反光强烈一些，某些区域弱一些。可以使用一张遮罩纹理来控制光照。
  2. 在制作地形材质时需要混合多张图片，例如表现草地的纹理，表现石子的纹理等，使用遮罩纹理可以控制如何混合这些纹理。

• 使用流程：通过采样得到遮罩纹理的纹素值，然后使用其中某个（或某几个）通道的值（如col.r）来与某种表面属性进行相乘，这样，当该通道的值为0时，可以保护表面不受该属性值得影响。

代码实现

Shader "zjt/Shader7_4_mask"
{
    Properties
    {
        _Color ("Color", Color) = (1,1,1,1)
        _MainTex ("Albedo (RGB)", 2D) = "white" {}
        _Glossiness ("Gloss", Range(10, 255)) = 100
        _Specular("Color", Color) = (1,1,1,1)
        _BumpTex("Bump Tex", 2D) = "bump"{}
        _BumpScale("BumpScale", Range(0,1)) = 1
        _MaskTex("Mask Tex", 2D) = "white"{}
        _MaskScale("MaskScale",Range(0,1)) = 1
    }
    SubShader
    {
        Tags { "RenderType"="Opaque" }
        LOD 200
        Pass
        {
            Tags{"LightMode"="ForwardBase"}
            CGPROGRAM
            #pragma vertex vert 
            #pragma fragment frag 
            #include "Lighting.cginc"

            fixed4 _Color;
            sampler2D _MainTex;
            float4 _MainTex_ST; 
            	// 三张纹理共同使用纹理属性变量，在材质面板中改变主纹理的平铺系数和偏移系数会影响3个纹理的采样
            	// 使用这种方式可以让我们节省需要存储的纹理坐标数目，如果为每个纹理都是用单独的属性变量 a_ST，那么随着使用的纹理数量增加，会迅速占满顶点着色器中可以使用的插值寄存器。而很多时候，不需要对纹理进行平铺和位移，或者很多纹理使用同一种平铺和位移。
            fixed4 _Specular;
            float _Glossiness;
            sampler2D _BumpTex;
            float _BumpScale;
            sampler2D _MaskTex;
            float _MaskScale;

            struct a2v
            {
                float4 position:POSITION;
                float4 tangent:TANGENT;
                float3 normal:NORMAL;
                float4 texcoord:TEXCOORD0;
            };

            struct v2f
            {
                float4 pos:SV_POSITION;
                float2 uv:TEXCOORD0;
                float3 tanLightDir:TEXCOORD1;
                float3 tanViewDir:TEXCOORD2;
            };

            v2f vert(a2v v)
            {
                v2f o;
                o.pos = UnityObjectToClipPos(v.position);
                o.uv.xy = TRANSFORM_TEX(v.texcoord, _MainTex);

                float3 y = cross(normalize(v.tangent.xyz), normalize(v.normal)) * v.tangent.w;
                float3x3 trans = float3x3(v.tangent.xyz, y, v.normal);
                o.tanLightDir = mul(trans, ObjSpaceLightDir(v.position)).xyz;
                o.tanViewDir = mul(trans, ObjSpaceViewDir(v.position)).xyz;
                return o;
            }

            fixed4 frag(v2f v):SV_Target
            {
                fixed3 tanLightDir = normalize(v.tanLightDir);
                fixed3 tanViewDir = normalize(v.tanViewDir);

                fixed4 unpackNor = tex2D(_BumpTex, v.uv);
                fixed3 tanNor = UnpackNormal(unpackNor);
                tanNor.xy *= _BumpScale;
                tanNor.z = sqrt(1 - saturate(dot(tanNor.xy, tanNor.xy)));

                // 漫反射，材质的反射系数
                fixed3 albedo = tex2D(_MainTex, v.uv).rgb * _Color.rgb;
                fixed3 ambient = UNITY_LIGHTMODEL_AMBIENT.xyz * albedo;
                fixed3 diffuse = _LightColor0.rgb * albedo * (0.5 * dot(tanNor, tanLightDir) + 0.5);

                fixed3 halfDir = normalize(tanLightDir + tanViewDir);
                fixed3 specular = _LightColor0.rgb * _Specular.rgb * pow(saturate(dot(tanNor, halfDir)), _Glossiness);

                // 遮罩
                fixed3 mask = tex2D(_MaskTex, v.uv).r * _MaskScale;
                specular *= mask;

                return fixed4(ambient + specular + diffuse, 1);
            }
            ENDCG
        }
    }
    FallBack "Diffuse"
}