遮罩纹理的使用

Go_Accepted

于 2024-08-22 00:07:13 发布

阅读量310

点赞数 4

分类专栏： Shader 文章标签： unity

本文链接：https://blog.csdn.net/Go_Accepted/article/details/141405131

版权

Shader 专栏收录该内容

20 篇文章 0 订阅

订阅专栏

1、遮罩纹理的使用

遮罩纹理通常用于控制或限制某些效果的显示范围。它允许我们可以保护某些区域，使它们免于某些修改。
一般情况下，遮罩纹理也会是一张灰度图，其中的RGB值会是相同的，我们利用它存储的值参与到：光照（指定某些区域受光影响的程度）、透明度（指定某些区域透明的程度）、特效（指定某些区域出现特效）等相关的计算中从而来让指定区域达到我们想要的效果

我们以高光遮罩纹理举例，下面三个胶囊体的对比就是高光遮罩纹理起到的效果，利用高光遮罩纹理，我们可以控制模型上的各个区域，受到高光影响的强弱

2、基本原理

高光遮罩纹理的基本原理是：

从纹理中取出对应的遮罩掩码值（颜色的RGB值都可以使用）
用该掩码值和遮罩系数(我们自己定义的)相乘得到遮罩值
用该遮罩值和高光反射计算出来的颜色相乘

最终呈现出来的高光反射表现就会受到 高光遮罩纹理 和 遮罩系数 的影响，从而表现出最终效果

3、代码实现

Shader "ShaderProj/2/MaskTex"
{
    Properties
    {
        _MainColor("MainColor", Color) = (1,1,1,1)
        _MainTex("MainTex", 2D) = ""{}
        _BumpMap("BumpMap", 2D) = ""{}
        _BumpScale("BumpScale", Range(0, 1)) = 1
        _SpecularColor("SpecularColor", Color) = (1,1,1,1)
        _SpecularNum("SpecularNum", Range(8, 256)) = 18
        _MaskTex("MaskTex", 2D) = ""{}
        _MaskScale("MaskScale", Float) = 1
    }
    SubShader
    {
        Tags { "LightMode"="ForwardBase" }
        LOD 100

        Pass
        {
            CGPROGRAM
            #pragma vertex vert
            #pragma fragment frag
            #include "UnityCG.cginc"
            #include "Lighting.cginc"

            sampler2D _MainTex;
            float4 _MainTex_ST;
            fixed4 _MainColor;
            sampler2D _BumpMap;
            float4 _BumpMap_ST;
            float _BumpScale;
            fixed4 _SpecularColor;
            float _SpecularNum;
            sampler2D _MaskTex;
            float _MaskScale;

            struct v2f
            {
                float4 pos:SV_POSITION;
                float4 uv:TEXCOORD0;
                float3 lightDir:TEXCOORD1;
                float3 viewDir:TEXCOORD2;
            };

            v2f vert (appdata_full v)
            {
                v2f data;

                data.pos = UnityObjectToClipPos(v.vertex);
                data.uv.xy = TRANSFORM_TEX(v.texcoord, _MainTex);
                data.uv.zw = TRANSFORM_TEX(v.texcoord, _BumpMap);

                float3 binormal = cross(normalize(v.tangent), normalize(v.normal)) * v.tangent.w;
                float3x3 transMat = float3x3(v.tangent.xyz,
                                             binormal,
                                             v.normal);
                data.lightDir = mul(transMat, ObjSpaceLightDir(v.vertex));
                data.viewDir = mul(transMat, ObjSpaceViewDir(v.vertex));

                return data;
            }

            fixed4 frag (v2f i) : SV_Target
            {
                float4 packedNormal = tex2D(_BumpMap, i.uv.zw);
                float3 tangentNormal = UnpackNormal(packedNormal);
                tangentNormal.xy *= _BumpScale;
                tangentNormal.z = sqrt(1.0 - saturate(dot(tangentNormal.xy, tangentNormal.xy)));

                fixed3 albedo = tex2D(_MainTex, i.uv.xy) * _MainColor.rgb;
                fixed3 lambertColor = _LightColor0 * albedo * max(0, dot(tangentNormal, normalize(i.lightDir)));

                float3 halfAngle = normalize(normalize(i.lightDir) + normalize(i.viewDir));
                // 高光遮罩纹理值的计算
                fixed maskColor = tex2D(_MaskTex, i.uv.xy).r;
                // 遮罩掩码值与遮罩系数相乘
                fixed maskNum = maskColor * _MaskScale;
                // 遮罩值与高光反射计算的颜色相乘
                fixed3 specularColor = _LightColor0 * _SpecularColor * pow(max(0, dot(tangentNormal, halfAngle)), _SpecularNum) * maskNum;
                fixed3 color = UNITY_LIGHTMODEL_AMBIENT * albedo + lambertColor + specularColor;

                return fixed4(color, 1);
            }
            ENDCG
        }
    }
}

看一看出高光部分是有差异的

4、遮罩纹理中的RGBA值

对于高光遮罩纹理中的RGBA值，是非常浪费的，因为我们只使用其中一个值就可以得到我们想要的数据，因此对于遮罩纹理来说，我们可以合理的利用其中的每一个值来存储我们想要的数据
可以在遮罩纹理当中存储更多信息
比如：R值代表高光遮罩数据、G值代表透明遮罩数据、B值代表特效遮罩数据等等
甚至可以用 n 张遮挡纹理存储 4xn 个会参与每个片元渲染计算的值