技术美术TA之全局光照全攻略（GI）

已于 2023-08-16 10:26:45 修改
阅读量504 收藏 3
点赞数 1
分类专栏： Unity-渲染 文章标签： 技术美术
于 2023-08-15 17:59:34 首次发布
版权声明：本文为博主原创文章，遵循 CC 4.0 BY-SA 版权协议，转载请附上原文出处链接和本声明。
本文链接：https://blog.csdn.net/qq_33064771/article/details/132268161
版权

本文是视频课程《Unity技术美术TA：Shader篇》，算是对自己学习的总结，也希望分享下所学知识~~

什么是全局光照？
Global Illumination，简称GI
既考虑来自光源的直接光照，又考虑经过场景中其他物体反射的光照

就是没有GI，阴影处很暗，但是现实情况确实也能看清
多了间接光照的处理

Unity 的 GI 实现方式
1.预计算实时GI
实时显示之前需要把数据进行烘焙好，运行时读取一遍实时和光源互动
（计算GI有延迟，不适合快速变化的灯光，适合昼夜变化缓慢变化的）

2.烘焙GI（常用）
把光源对场景中静态物体的光照效果提前烘焙到一张张光照纹理
把光照纹理采样到物体表面以产生全局光照的效果
（固定的光源方向，不能有变化）

Unity 烘焙系统
1.Enlighten，旧版烘焙技术，已经被2021中淘汰
2.Progressive CPU Lightmapper，渐进式烘焙
基于路径追踪的烘焙系统
会先烘焙当前scene预览的画面，方便查看
3.Progressive GPU Lightmapper（在GPU计算）

烘焙设置：
Baked Indirect：只烘焙间接光
Subtractive：直接光+间接光
Shadowmask：阴影相关
（在Baked Indirect的基础上， 多烘焙了一张Shadowmask贴图）

烘焙设置界面：
Windows->Rendering->Lighting
在这里插入图片描述

其中设置项：
Realtime Lighting：实时 GI （Realtime Global Illumination，标识是否开启）
Mixed Lighting：烘焙GI （Baked Global Illumination，标识是否开启）
Lightmap Compression：贴图压缩设置
Ambient Occlusion：环境光遮挡（阻挡光区域处更黑）

Generate Lighting 按钮：开始烘焙

注意：
场景物体需要标记为 static（或者单独设置 Contribute GI）

场景灯光要设置为 Mixed 或者Baked

Shader 代码如下

Shader "Custom/TA/GlobalIllumination"
{
    Properties {}
    SubShader
    {
        Tags
        {
            "LightMode"="ForwardBase"
        }

        Pass
        {
            CGPROGRAM
            #pragma vertex vert
            #pragma fragment frag
            #pragma multi_compile_fwdbase

            #include "UnityCG.cginc"
            #include "Lighting.cginc"
            #include "AutoLight.cginc"
            #include "CgIncludes/MyGlobalIllumination.cginc"

            struct appdata
            {
                float4 vertex : POSITION;
                float2 uv : TEXCOORD0;
                float3 normal : NORMAL;

                #if defined(LIGHTMAP_ON)
                    //一般光照贴图都是第二套UV
                    float4 texcoord1 : TEXCOORD1;
                #endif
            };

            struct v2f
            {
                float4 vertex : SV_POSITION;
                float3 worldNormal : TEXCOORD0;
                float3 worldPos : TEXCOORD1;

                #if defined(LIGHTMAP_ON)
                    //一般光照贴图都是第二套UV
                    float4 lightmapUV : TEXCOORD2;
                #endif
            };

            v2f vert(appdata v)
            {
                v2f o;
                o.vertex = UnityObjectToClipPos(v.vertex);
                o.worldNormal = UnityObjectToWorldNormal(v.normal);
                o.worldPos = mul(unity_ObjectToWorld, v.vertex).xyz;

                //BakeGI
                #if defined(LIGHTMAP_ON)
                o.lightmapUV.xy = v.texcoord1 * unity_LightmapST.xy + unity_LightmapST.zw;
                #endif

                //RealTimeGI
                #if defined(DYNAMICLIGHTMAP_ON)
                o.lightmapUV.zw = v.texcoord1 * unity_LightmapST.xy + unity_LightmapST.zw;
                #endif
                
                return o;
            }

            fixed4 frag(v2f i) : SV_Target
            {
                //表面信息
                SurfaceOutput o;
                UNITY_INITIALIZE_OUTPUT(SurfaceOutput, o);
                o.Albedo = 1;
                o.Normal = i.worldNormal;
                
                //GI 输入信息（要什么给什么）
                UnityGIInput giInput = (UnityGIInput)0;
                // UNITY_INITIALIZE_OUTPUT(UnityGIInput, giInput);
                giInput.light.color = _LightColor0;
                giInput.light.dir = _WorldSpaceLightPos0;
                giInput.worldPos = i.worldPos;
                giInput.worldViewDir = normalize(_WorldSpaceCameraPos - i.worldPos);
                giInput.atten = 1;
                giInput.ambient = unity_AmbientSky;
                #if defined(LIGHTMAP_ON) || defined(DYNAMICLIGHTMAP_ON)
                giInput.lightmapUV = i.lightmapUV;
                #endif

                //GI 输出信息
                //间接光照计算存储在这里
                UnityGI gi;
                UNITY_INITIALIZE_OUTPUT(UnityGI, gi);

                CUSTOM_LightingLambert_GI(o, giInput, gi);

                //直接光照计算
                fixed4 c = CUSTOM_LightingLambert(o, gi);
                return c;
            }
            ENDCG
        }
    }
}

其中 #include "CgIncludes/MyGlobalIllumination.cginc" 是自定义 cginc 文件：
作用是计算直接光照+简介光照
（就是 Unity 内置的GI shader，拷贝出来的，方法前加 CUSTOM_ ）

代码如下：

#ifndef MYGLOBALILLUMINATION_CGINCLUDE
#define MYGLOBALILLUMINATION_CGINCLUDE

//兰伯特光照模型
inline fixed4 CUSTOM_UnityLambertLight(SurfaceOutput s, UnityLight light)
{
    fixed diff = max(0, dot(s.Normal, light.dir));

    fixed4 c;
    c.rgb = s.Albedo * light.color * diff;
    c.a = s.Alpha;
    return c;
}

//计算直接光照+间接光照的影响
inline fixed4 CUSTOM_LightingLambert(SurfaceOutput s, UnityGI gi)
{
    fixed4 c;
    c = CUSTOM_UnityLambertLight(s, gi.light);

    //  LIGHTMAP_ON          =>     BakeGI
    //  DYNAMICLIGHTMAP_ON   =>     RealtimeGI

    // #if defined(LIGHTMAP_ON) || defined(DYNAMICLIGHTMAP_ON)
    // #define UNITY_LIGHT_FUNCTION_APPLY_INDIRECT
    // #endif

    //如果是BakeGI 或者 RealTimeGI 条件下
    #ifdef UNITY_LIGHT_FUNCTION_APPLY_INDIRECT
    c.rgb += s.Albedo * gi.indirect.diffuse;
    #endif

    return c;
}

//GI的核心
inline UnityGI CUSTOM_UnityGI_Base(UnityGIInput data, half occlusion, half3 normalWorld)
{
    // 储存结果，最后返回
    UnityGI o_gi;
    ResetUnityGI(o_gi);

    //计算 shadow相关的， DistanceShadow 实时阴影和烘焙阴影的过度
    // Base pass with Lightmap support is responsible for handling ShadowMask / blending here for performance reason
    #if defined(HANDLE_SHADOWS_BLENDING_IN_GI)
        half bakedAtten = UnitySampleBakedOcclusion(data.lightmapUV.xy, data.worldPos);
        float zDist = dot(_WorldSpaceCameraPos - data.worldPos, UNITY_MATRIX_V[2].xyz);
        float fadeDist = UnityComputeShadowFadeDistance(data.worldPos, zDist);
        data.atten = UnityMixRealtimeAndBakedShadows(data.atten, bakedAtten, UnityComputeShadowFade(fadeDist));
    #endif

    //主平行灯传入 gi
    o_gi.light = data.light;
    //作用衰减值
    o_gi.light.color *= data.atten;

    //是否进行球谐光计算
    #if UNITY_SHOULD_SAMPLE_SH
        o_gi.indirect.diffuse = ShadeSHPerPixel(normalWorld, data.ambient, data.worldPos);
    #endif

    //如果使用烘焙GI
    #if defined(LIGHTMAP_ON)

        //光照贴图的采样 xy是烘焙GI的 uv
        // Baked lightmaps
        half4 bakedColorTex = UNITY_SAMPLE_TEX2D(unity_Lightmap, data.lightmapUV.xy);
        half3 bakedColor = DecodeLightmap(bakedColorTex);

    //Direction Mode 如果为 Direction，会计算相关光照方向，增加纹理凹凸感
    #ifdef DIRLIGHTMAP_COMBINED
            fixed4 bakedDirTex = UNITY_SAMPLE_TEX2D_SAMPLER (unity_LightmapInd, unity_Lightmap, data.lightmapUV.xy);
            o_gi.indirect.diffuse += DecodeDirectionalLightmap (bakedColor, bakedDirTex, normalWorld);

    #if defined(LIGHTMAP_SHADOW_MIXING) && !defined(SHADOWS_SHADOWMASK) && defined(SHADOWS_SCREEN)
                ResetUnityLight(o_gi.light);
                o_gi.indirect.diffuse = SubtractMainLightWithRealtimeAttenuationFromLightmap (o_gi.indirect.diffuse, data.atten, bakedColorTex, normalWorld);
    #endif

    // 如果为 non-Directional 就是直接取bakeColor
    #else // not directional lightmap
            o_gi.indirect.diffuse += bakedColor;

    #if defined(LIGHTMAP_SHADOW_MIXING) && !defined(SHADOWS_SHADOWMASK) && defined(SHADOWS_SCREEN)
                ResetUnityLight(o_gi.light);
                o_gi.indirect.diffuse = SubtractMainLightWithRealtimeAttenuationFromLightmap(o_gi.indirect.diffuse, data.atten, bakedColorTex, normalWorld);
    #endif

    #endif
    #endif

    //如果使用实时GI
    #ifdef DYNAMICLIGHTMAP_ON

        //光照贴图的采样 zw是烘焙GI的 uv
        // Dynamic lightmaps
        fixed4 realtimeColorTex = UNITY_SAMPLE_TEX2D(unity_DynamicLightmap, data.lightmapUV.zw);
        half3 realtimeColor = DecodeRealtimeLightmap (realtimeColorTex);

    #ifdef DIRLIGHTMAP_COMBINED
            half4 realtimeDirTex = UNITY_SAMPLE_TEX2D_SAMPLER(unity_DynamicDirectionality, unity_DynamicLightmap, data.lightmapUV.zw);
            o_gi.indirect.diffuse += DecodeDirectionalLightmap (realtimeColor, realtimeDirTex, normalWorld);
    #else
            o_gi.indirect.diffuse += realtimeColor;
    #endif
    #endif

    //diffuse 就是最后得出的间接光颜色 作用于环境光遮蔽
    o_gi.indirect.diffuse *= occlusion;
    return o_gi;
}

inline UnityGI CUSTOM_UnityGlobalIllumination(UnityGIInput data, half occlusion, half3 normalWorld)
{
    return CUSTOM_UnityGI_Base(data, occlusion, normalWorld);
}

inline void CUSTOM_LightingLambert_GI(SurfaceOutput s, UnityGIInput data, inout UnityGI gi)
{
    gi = CUSTOM_UnityGlobalIllumination(data, 1.0, s.Normal);
}


#endif

对于阴影有两种
1.实时阴影（随着光变化）
2.烘焙阴影（固定的）

对于 Distance Shadowmask，可以设置实时阴影和烘焙阴影的切换距离
在这里插入图片描述
过渡效果如下：
在这里插入图片描述

支持shadow的代码


Shader "Custom/TA/GlobalIllumination"
{
    Properties {}
    SubShader
    {
        Pass
        {
            struct v2f
            {
            	...
            
                //定义 shadow
                //unityShadowCoord4 _ShadowCoord : TEXCOORD##idx1;
                //unityShadowCoord4 _LightCoord : TEXCOORD##idx;
                UNITY_LIGHTING_COORDS(3, 4)
            };

            v2f vert(appdata v)
            {
            	...

                //计算 shadow
                //a._LightCoord = mul(unity_WorldToLight, mul(unity_ObjectToWorld, v.vertex)).xy;
                //a._ShadowCoord.xy = coord.xy * unity_LightmapST.xy + unity_LightmapST.zw;
                UNITY_TRANSFER_LIGHTING(o, v.texcoord1.xy)
                
                return o;
            }

            fixed4 frag(v2f i) : SV_Target
            {
            	...

                //灯光的衰减效果 + 阴影纹理采样
                UNITY_LIGHT_ATTENUATION(atten, i, i.worldPos);
                
                ...
                
                //赋值
                giInput.atten = atten;
	
                
                #endif
                
            }
            ENDCG
        }
		
		//需要 shadowcaster
		UsePass "XXX/SHADOW_CASTER"
    }
}

光照探针
烘焙是静态的，但是场景中的物体是动态的
光照探针就是为了让物体也受到烘焙效果

对比光照探针的效果
在这里插入图片描述
在这里插入图片描述

代码支持如下

Shader "Custom/TA/GlobalIllumination"
{
    SubShader
    {
        Pass
        {
            struct v2f
            {
            	...

                #if UNITY_SHOULD_SAMPLE_SH
                    half3 sh : TEXCOORD3;
                #endif
            };

            v2f vert(appdata v)
            {
            	...

                //球谐光照和顶点光照的计算
                // SH/ambient and vertex lights
                #ifndef LIGHTMAP_ON //如果没有开启烘焙
                //是否启用球谐 并且 不是逐片断的执行SH采样
                #if UNITY_SHOULD_SAMPLE_SH && !UNITY_SAMPLE_FULL_SH_PER_PIXEL
                    o.sh = 0;
                //非重要级别的点光在逐顶点的光照效果
                #ifdef VERTEXLIGHT_ON
                    //逐顶点光照（只计算4个灯）
                    o.sh += Shade4PointLights (
                      unity_4LightPosX0, unity_4LightPosY0, unity_4LightPosZ0,
                      unity_LightColor[0].rgb, unity_LightColor[1].rgb, unity_LightColor[2].rgb, unity_LightColor[3].rgb,
                      unity_4LightAtten0, o.worldPos, o.worldNormal);
                #endif
                    //球谐，光照探针效果
                    o.sh = ShadeSHPerVertex (o.worldNormal, o.sh);
                #endif
                #endif


                return o;
            }

            fixed4 frag(v2f i) : SV_Target
            {
            	...

                //光照计算（包括反射探针）
                #if UNITY_SHOULD_SAMPLE_SH && !UNITY_SAMPLE_FULL_SH_PER_PIXEL
                giInput.ambient = i.sh;
                #else
                giInput.ambient.rgb = 0;
                #endif
            }
            ENDCG
        }

    }
}

间接光的 Meta Pass
自发光颜色烘焙时会对其他物体产生影响
在这里插入图片描述

只会在烘焙执行，运行游戏不会执行

注意：需要设置 Flags为2
在这里插入图片描述

代码如下

Shader "Custom/TA/GlobalIllumination"
{
    Properties
    {
        _Color("Color",color)=(1,1,1,1)
    }
    SubShader
    {
    	...
    
        //计算光照的间接光反弹
        Pass
        {
            Name "META"
            Tags
            {
                "LightMode" ="Meta"
            }

            CGPROGRAM
            #pragma vertex vert
            #pragma fragment frag
            #pragma target 2.0
            #include "UnityCG.cginc"
            #include "UnityMetaPass.cginc"

            fixed4 _Color;

            struct v2f
            {
                float4 pos : SV_POSITION;
            };

            v2f vert(appdata_full v)
            {
                v2f o;
                    UNITY_INITIALIZE_OUTPUT(v2f, o);
                o.pos = UnityMetaVertexPosition(v.vertex,
                    v.texcoord1.xy, v.texcoord2.xy,
                    unity_LightmapST, unity_DynamicLightmapST);
                return o;
            }

            half4 frag(v2f i) : SV_Target
            {
                UnityMetaInput metaIN;
                    UNITY_INITIALIZE_OUTPUT(UnityMetaInput, metaIN);
                metaIN.Albedo = 1;
                metaIN.Emission = _Color;
                return UnityMetaFragment(metaIN);
            }
            ENDCG
        }
    }
    
}

代码优化
1.烘焙的shader 可以和运行 shader作区分
（烘焙的复杂，运行的简单，删除一些没用的功能）
2.确定不要的分支可以删掉，精简代码
（比如只用 BakeGI）

东北砍王
关注
专栏目录
实时渲染 -- 全局光照（Global Illumination）
gghhb12的博客
04-14 1546
我们今天的课程主题是动态全局光照和Lumen ，在讲Lumen之前，我们需要首先需要了解GI（Global Illumination），如果不把GI讲清楚，大家将会陷入Lumen复杂深邃的技术细节中。如果不了解GI的发展演变，大家会感觉Lumen中的某些细节处理是凭空从天上掉下来的。但其实不然，Lumen中的很多算法和思想在之前的一些GI算法中都有出现和实践过，因此Lumen更像一个各种GI算法的集大成者。我们只有理解GI最宏观的体系结构，你才能理解Lumen 是怎么产生的。
全局光照技术解析Global Illumination Explained
07-08 1132
解析全局光照Global Illumination Explained 前言：Global Illumination全局光照技术是实时渲染的必然发展方向。我参考了一些研究成果，琢磨了一下，让更多的人可以理解这项“古老”的技术。 Front Line 虽然说，如今的GPU速度已经非常之快，并行浮点计算能力已经相当的强大，但是由于很多人依旧使用传统的Phong局部光照模型对场景进行Shading处理，所以成像效果上还远远不能够与离线渲染的图像相比。如让我们目瞪口呆的Unreal Engine3，技术规
动态光照和全局光照
最新发布
听老罗娓娓道来
09-05 388
动态光照和全局光照是游戏引擎中实现真实感光照效果的重要技术。动态光照通过实时计算光源和物体的交互来模拟动态光照效果，而全局光照则通过考虑光线在场景中的多次反射和散射来实现更真实的光照效果。实现这些技术需要结合多种算法和技术，并根据具体的游戏需求和硬件性能进行优化和调整。
技术美术入门
zaizai1007的博客
09-03 878
技术美术入门(render,mesh)
MAYA_GI灯光插件生成
02-20
MAYA的GI插件,能快速生成全局灯光组,并集成进行设置
全局光照（简述）
热门推荐
weixin_43022263的博客
05-11 1万+
一、什么是全局光照 全局光照（Global Illumination,简称 GI）， 作为图形学中比较酷的概念之一，是指既考虑场景中来自光源的直接光照，又考虑经过场景中其他物体反射后的间接光照的一种渲染技术。 即可以理解为：全局光照 = 直接光照(Direct Light) + 间接光照(Indirect Light) 图1 Direct illumination （原图连接） 图2 Global illumination = Direct illumination +Indirect illumina
全局光照技术(一)
qq_41940565的博客
02-03 498
全局光照技术(一)
Unity学习日志_全局光照GI系统简介
BraveRunTo的博客
01-20 2276
Unity学习日志_GI系统简介 1. 何为GI？ 全局光照，简称为GI，是一个用来模拟光的互动和反弹等复杂行为的算法。要精确的仿真全局光照非常的具有挑战性，付出的代价也很高，正因如此，现代游戏会在一定程度上预先处理这些计算，而非在游戏运行时实时计算。Unity的全局光照系统分为Enlighten和Progressive Lightmapper，两者之间可以通过lighting窗口进行切换。 在Unity的5.6版本之前的5.x中，主要使用了Geomerics公司的Enlighten来提供实时全局照明以
Unity 5 全局光照GI与新的烘焙系统初探
N的专栏
12-16 1758
GI是啥 Realtime GI，实时全局光照，听上去就是一个非常高大上的词，但是越高大上就越令人心生敬畏，因为世上没有免费的午餐，越好的效果意味着越多的消耗，对于移动平台来说，这样的消耗受不受的起呢？首先来说说GI是干啥的，非常粗略的来描述下，如果说我们以前的光照系统就是由光源 - 物体 - 视点组成的话，那么全局光照系统就是由光源 - n多环境反射光 - 物体 - 视点。就是说GI额外包
C4D的GI(全局光照)[汇编].pdf
10-11
总结来说，全局光照（GI）是C4D中提升场景真实感的重要工具，通过HDRIs技术实现了光照的多角度计算，使得3D渲染的图像更加接近现实。理解并熟练运用这些技术，将有助于提升3D艺术作品的质量，让光影效果更具吸引力和...
【全局光照GI系统剖析_直接和间接光照_案例分享(附带场景下载链接)_场景】
暴走约伯的博客
12-22 1225
全局照明(Global Illumination)由两个部分组成，直接光照(Direct Light)和间接光照(Indirect Light)。直接光的光照(Direct Light)是通过主灯或者其他类型灯与参与光照的物体实时计算出的，其中直接光漫反射也会参与LightMap和LightProbe的预计算。间接光照(Indirect Light)主要实现的是间接光漫反射的光照效果。一版通过LightMap和实现。
Unity 5 中的全局光照技术详解.pdf
11-20
全局光照（Global Illumination, 简称GI）是Unity引擎中的关键技术，用于模拟光在游戏环境中复杂的互动和反弹现象，以实现更为真实的光照效果。Unity 5引入了多种全局光照解决方案，包括实时照明、烘焙全局光照和...
（六）unity自带的着色器源码剖析之——————Unity3D的全局光照和阴影：上篇（全局照明GI和局部照明）
cgy56191948的博客
04-23 1688
一、全局照明和局部照明 全局照明(global illumination，GI)是用于向三维场景中添加更为逼真的光照效果的一组算法总称。全局算法不仅考虑光源发出的光与被照亮物体之间的关系，即直接照明（direct illumination），还考虑光线从某一物体的表面传递到另一个物体的表面时的关系，即间接照明（indirect illmination）。而局部照明(local illuminat...
Unity实时全局光照和烘焙全局光照 Unity2019
12-04 1万+
1、全局光照GI 全局照明是一个系统，用于模拟光从表面反射到其他表面（间接光）的方式，而不仅仅是直接从光源（直接光）照射到表面的光。 全局光照=直接光+间接光 没有光照的地方是一片死黑；可以想象现实生活中，一束光投进窗户，从而整个房间的阴暗角落也会被照亮，这就是间接光效的效果。 但间接光照的算法非常复杂，计算速度太慢 方案一：只为预先知道不会移动的物体计算间接光照 多个物体之间谈全局光照才有意义。 全局光照和烘焙密不可分。 Unity3d的最终作品是供受众对3D场景进行实时操作的，就像.
全局光照技术：Precomputed Radiance Transfer
JMXIN422的博客
04-01 1856
1. 介绍 物体在不同光照下的表现不同，PRT（Precomputed Radiance Transfer）是一 个计算物体在不同光照下表现的方法。光线在一个环境中，会经历反射，折射， 散射，甚至还会在物体的内部进行散射。为了模拟具有真实感的渲染结果，传统的 Path Tracing 方法需要考虑来自各个方向的光线、所有可能的传播形式，并且收敛速度极慢。PRT使用一种预计算方法，该方法在离线渲染的 Path Tracing 工具链中预计算 lighting以及 light transport， 并将它们用球
全局光照
climb
02-12 4070
原文连接：全局光照 全局光照 GI概念 GI的局限性 GI效果的例子 全局光照 全局光照是一种表达光线从表面反射到另一个表面（间接光）的工作方式的模型，而不仅限于从光源直接击中表面的光（直接光）。使用间接光能使虚拟世界看起来更加真实和相互连接，因为物体之间相互影响显示效果。一个经典的例子是“颜色出血”效果。比如太阳光照射一个红色沙发时，红光会被反射到沙发后面的墙上。另...
实时渲染学习（七）全局光照：光线追踪、路径追踪与GI技术进化编年史
ljytower的博客
04-17 1万+
参考博文【《Real-Time Rendering 3rd》 提炼总结】(八) 第九章 · 全局光照:光线追踪、路径追踪与GI技术进化编年史 前言 本章知识概览： 全局光照的基本概念 全局光照的算法主要流派 全局光照技术进化编年史 光线追踪 Ray Tracing 路径追踪 Path Tracing 光线追踪、路径追踪、光线投射的区别 环境光遮蔽 Ambient Occlusion 一、全局光...
unity 全局光照
现在学习也不晚
03-29 2895
直接光照由直接光照射到物体上以后直接弹射到人眼接收到的光照。间接光照为直接光照照射到物体上又弹射到其它物体上面以后多次弹射才被人眼接收的光照（两次及以上的光照统称为间接光照）
评论
添加红包

请填写红包祝福语或标题

个

红包个数最小为10个

元

红包金额最低5元

当前余额3.43元 前往充值 >
需支付：10.00元
成就一亿技术人!
领取后你会自动成为博主和红包主的粉丝 规则
hope_wisdom
发出的红包
实付元
使用余额支付
点击重新获取
扫码支付
钱包余额 0

抵扣说明：

1.余额是钱包充值的虚拟货币，按照1:1的比例进行支付金额的抵扣。
2.余额无法直接购买下载，可以购买VIP、付费专栏及课程。

余额充值