ReflectCubeMap

最新推荐文章于 2023-07-26 11:44:39 发布

ThomasQxx

最新推荐文章于 2023-07-26 11:44:39 发布

阅读量111

点赞数

分类专栏： Unity_Shader 文章标签： shader

本文链接：https://blog.csdn.net/qq_39691716/article/details/120487683

版权

Shader 反射 CubeMap 纹理采样光照模型

关键词由CSDN通过智能技术生成

Unity_Shader 专栏收录该内容

25 篇文章 3 订阅

订阅专栏

Shader来实现反射效果：通过相机的视角方向和物体模型的法线方向来计算反射方向。然后通过反射方向在CubeMap当中进行采样。采样得到的结果和主纹理进行线性插值。

Shader "QShader/ReflectCubeMap"{
    Properties{
        _MainTex("Main Texture",2D) = "white"{}
        _BaseColor("Base Color",Color) = (1.0,1.0,1.0,1.0)
        _ReflectColor("Reflection Color",Color) = (1.0,1.0,1.0,1.0)
        _ReflectAmount("Reflection Amount",Range(0,1)) = 1
        _Cubemap("Reflection Cubemap",Cube) = "skybox"{}
    }
        SubShader{
            pass {
                Tags{"LightMode" = "ForwardBase"}
                CGPROGRAM
                #include "UnityCG.cginc"
                #include "Lighting.cginc"
                #include "AutoLight.cginc"
                #pragma vertex Vertex
                #pragma fragment Fragment

                struct a2v {
                    float4 vertex : POSITION;
                    float3 normal : NORMAL;
                    float4 texcoord : TEXCOORD0;
                };

                struct v2f {
                    float4 pos : SV_POSITION;
                    float3 worldNormal : TEXCOORD0;
                    float3 worldPos : TEXCOORD1;
                    float3 worldViewDir : TEXCOORD2;
                    float3 worldReflectDir : TEXCOORD3;
                    float2 uv : TEXCOORD4;
                    //SHADOW_COORDS 声明了一个名为_ShadowCoord的阴影纹理坐标变量。
                    //它的作用是声明一个用于对阴影纹理采样的uv坐标。一般用于片元着色器的输入结构体中，
                    //而且这个宏的参数需要是下一个可用插值寄存器的索引值，这里是5。
                    SHADOW_COORDS(5)
                };

                fixed4 _BaseColor;
                fixed _ReflectAmount;
                fixed4 _ReflectColor;
                samplerCUBE _Cubemap;
                sampler2D _MainTex;

                v2f Vertex(a2v v) {

                    v2f o;
                    o.pos = UnityObjectToClipPos(v.vertex);
                    o.worldNormal = UnityObjectToWorldNormal(v.normal);
                    o.worldPos = mul(unity_ObjectToWorld,v.vertex).xyz;
                    o.worldViewDir = UnityWorldSpaceViewDir(o.worldPos);
                    o.worldReflectDir = reflect(-o.worldViewDir,o.worldNormal);
                    o.uv = v.texcoord;
                    TRANSFER_SHADOW(o)
                    return o;
                }
                 
                fixed4 Fragment(v2f i) :SV_TARGET{

                    fixed3 worldNormal = normalize(i.worldNormal);
                    fixed3 worldLightDir = normalize(UnityWorldSpaceLightDir(i.worldPos));
                    fixed3 worldViewDir = normalize(i.worldViewDir);

                    fixed3 albedo = tex2D(_MainTex,i.uv).xyz * _BaseColor.xyz;

                    fixed3 ambient = UNITY_LIGHTMODEL_AMBIENT.xyz * albedo;
                    fixed3 diffuse = _LightColor0.xyz * albedo * saturate(dot(worldNormal,worldLightDir));

                    fixed3 reflection = texCUBE(_Cubemap,i.worldReflectDir).xyz * _ReflectColor.xyz;

                    UNITY_LIGHT_ATTENUATION(atten,i,i.worldPos);

                    fixed3 color = ambient + lerp(diffuse,reflection,_ReflectAmount) * atten;
                    return fixed4(color,1.0);

                }

                ENDCG
            }
    }
}