Unity 流光shader的思路

先看一下直线方程：

1.x+0.5y=0:

2.x+0.5y=20:

 3.由上面的函数图像可以看出 z=x+ky (k是常量)，表示所有斜率为k的直线集合，z是直线在x轴的截距，每个z的取值都确定一条唯一的斜率为k的直线。

4.那么给z一个取值范围就可以画出一条斜的条纹，下面我们根据这个思路，用shader在图片上画一条静态的条纹光线：

float _Speed; 
float _Width; 
float _Angle; 	//光的倾斜角度
float _Intensity;  //光的强度
float4 _LightColor; //光的颜色

fixed4 frag (v2f i) : SV_Target
{
	fixed4 col = tex2D(_MainTex, i.uv);
	float z = i.uv.x + i.uv.y * _Angle;
	if(z>0.6&& z<0.8){
		float3 target = _LightColor.rgb + col.rgb;
		col.rgb = lerp(col.rgb, target, _Intensity);
	}
	
	return col;
}

 效果如下：

 让光线动起来就简单了只需要让z随着时间不断增加或减少，完整代码如下：

Shader "Unlit/liuguang"
{
	Properties
	{
		_MainTex ("Texture", 2D) = "white" {}
		
		// 速度 默认左->右
		_Speed ("Speed", range(-2, 2)) = 1.04
		
		// 宽度
		_Width ("Width", range(1, 10)) = 5.83

		// 角度
		_Angle ("Angle", range(-1, 1)) = 0.33

		// 亮度
		_Intensity ("Intensity", range(0, 1)) = 0.51

		_LightColor ("LightColor", Color) = (1,1,1,1)

	}
	SubShader
	{
		Tags { "RenderType"="Opaque" }
		LOD 100

		Pass
		{
			CGPROGRAM
			#pragma vertex vert
			#pragma fragment frag
			
			#include "UnityCG.cginc"

			struct appdata
			{
				float4 vertex : POSITION;
				float2 uv : TEXCOORD0;
			};

			struct v2f
			{
				float2 uv : TEXCOORD0;
				float4 vertex : SV_POSITION;
			};

			sampler2D _MainTex;
			
			v2f vert (appdata v)
			{
				v2f o;
				o.vertex = UnityObjectToClipPos(v.vertex);
				o.uv = v.uv;
				return o;
			}
			
			float _Speed; 
			float _Width; 
			float _Angle; 	//光的倾斜角度
			float _Intensity;  //光的强度
			float4 _LightColor; //光的颜色
			fixed4 frag (v2f i) : SV_Target
			{
				fixed4 col = tex2D(_MainTex, i.uv);
				float z = i.uv.x + i.uv.y * _Angle;
				//z + _Time.w * _Speed 可以修改光流动方向，也可以通过_Speed的正负改变
				float flowX = sin(z - _Time.w * _Speed);
				if(flowX>0.1&& flowX<0.1+_Width*0.1){
					float3 target = _LightColor.rgb + col.rgb;
					col.rgb = lerp(col.rgb, target, _Intensity);
				}
				
				return col;
			}
			ENDCG
		}
	}
}