【状态机设计】Moore、Mealy状态机、三段式、二段式、一段式状态机书写规范

已于 2022-12-07 16:03:05 修改
阅读量5.1k 收藏 107
点赞数 19
分类专栏： FPGA Verilog 文章标签： fpga开发 FSM 状态机 Verilog 三段式状态机
于 2022-06-27 08:00:00 首次发布
版权声明：本文为博主原创文章，遵循 CC 4.0 BY-SA 版权协议，转载请附上原文出处链接和本声明。
本文链接：https://blog.csdn.net/m0_61298445/article/details/125470553
版权
Verilog 同时被 2 个专栏收录
36 篇文章 92 订阅
订阅专栏
FPGA
33 篇文章 71 订阅
订阅专栏

目录

状态机介绍

状态机类型

Moore 型状态机

Mealy 型状态机

状态机设计流程

自动售卖机

状态机设计：3 段式（推荐）

实例

实例

状态机修改：2 段式

实例

状态机修改：1 段式（慎用）

实例

状态机修改：Moore 型

实例

实例

 

状态机介绍

有限状态机（Finite-State Machine，FSM），简称状态机，是表示有限个状态以及在这些状态之间的转移和动作等行为的数学模型。状态机不仅是一种电路的描述工具，而且也是一种思想方法，在电路设计的系统级和 RTL 级有着广泛的应用。

都说状态机是 FPGA 设计的灵魂，可见其重要之处，在 Verilog 的设计中，状态机其实可以等同于 if 语句和 case 语句，但是由于在某些情况下，状态的种类多且复杂，各种状态跳转起来非常麻烦，所以 一般利用状态机设计是一种可靠便捷的方法。

规范的状态机代码可以极大地提高设计效率， 在减少状态出错可能的同时缩短调试时间， 从而设计出稳健的系统。

在设计状态机时，最好能够满足以下要求：

  • 通用的设计方法， 针对简单或复杂的状态机设计都能满足；
  • 步骤清晰易懂， 每步只考虑一个问题；
  • 状态机代码严谨规范， 不容易出错；
  • 设计的状态机结构简单且稳定。

状态机类型

Verilog 中状态机主要用于同步时序逻辑的设计，能够在有限个状态之间按要求和规律切换时序电路的状态。状态的切换方向不但取决于各个输入值，还取决于当前所在状态。 状态机可分为两类：

  • Moore 状态机
  • Mealy 状态机

Moore 型状态机

Moore 型状态机的输出只与当前状态有关，与当前输入无关。

输出会在一个完整的时钟周期内保持稳定，即使此时输入信号有变化，输出也不会变化。输入对输出的影响要到下一个时钟周期才能反映出来。这也是 Moore 型状态机的一个重要特点：输入与输出是隔离开来的。

4d4c3c3c99964c879e4ea6c46e5e9e6a.png

 

 

Mealy 型状态机

Mealy 型状态机的输出，不仅与当前状态有关，还取决于当前的输入信号。

Mealy 型状态机的输出是在输入信号变化以后立刻发生变化，且输入变化可能出现在任何状态的时钟周期内。因此，同种逻辑下，Mealy 型状态机输出对输入的响应会比 Moore 型状态机早一个时钟周期。

1b209e2630964d6f95af242981dc3290.png

 

 

状态机设计流程

根据设计需求画出状态转移图，确定使用状态机类型，并标注出各种输入输出信号，更有助于编程。一般使用最多的是 Mealy 型 3 段式状态机，下面用通过设计一个自动售卖机的具体实例来说明状态机的设计过程。

自动售卖机

自动售卖机的功能描述如下：

饮料单价 2 元，该售卖机只能接受 0.5 元、1 元的硬币。考虑找零和出货。投币和出货过程都是一次一次的进行，不会出现一次性投入多币或一次性出货多瓶饮料的现象。每一轮售卖机接受投币、出货、找零完成后，才能进入到新的自动售卖状态。

该售卖机的工作状态转移图如下所示，包含了输入、输出信号状态。

其中，coin = 1 代表投入了 0.5 元硬币，coin = 2 代表投入了 1 元硬币。

16b9290bf40f4e949775cbd17a5cb890.png

状态机设计：3 段式（推荐）

状态机设计如下：

  • (0) 首先，根据状态机的个数确定状态机编码。利用编码给状态寄存器赋值，代码可读性更好。
  • (1) 状态机第一段，时序逻辑，非阻塞赋值，传递寄存器的状态。
  • (2) 状态机第二段，组合逻辑，阻塞赋值，根据当前状态和当前输入，确定下一个状态机的状态。
  • (3) 状态机第三段，时序逻辑，非阻塞赋值，因为是 Mealy 型状态机，根据当前状态和当前输入，确定输出信号。

实例

module  vending_machine_p3  (
    input           clk ,
    input           rstn ,
    input [1:0]     coin ,     

    output [1:0]    change ,     //找零
    output          sell         //输出饮料
    );

    //machine state decode
    parameter           IDLE   = 3'd0 ;
    parameter           GET05  = 3'd1 ;
    parameter           GET10  = 3'd2 ;
    parameter           GET15  = 3'd3 ;

   
     
    reg  [2:0]          st_next ;
    reg  [2:0]          st_cur ;
    reg  [1:0]          change_r ;
    reg           	sell_r ;

    //第一段状态机，时序逻辑 非阻塞赋值
    always @(posedge clk or negedge rstn) begin
        if (!rstn) begin
            st_cur <= 'b0 ;
        end
        else begin
            st_cur <= st_next ;
        end
    end

    //第二段状态机 ，组合逻辑 阻塞赋值  
    always @(*) begin
        st_next = st_cur ;        //如果条件选项考虑不全，可以赋初值消除latch
        case(st_cur)
            IDLE:
                case (coin)
                    2'b01:     st_next = GET05 ;
                    2'b10:     st_next = GET10 ;
                    default:   st_next = IDLE ;
                endcase
            GET05:
                case (coin)
                    2'b01:     st_next = GET10 ;
                    2'b10:     st_next = GET15 ;
                    default:   st_next = GET05 ;
                endcase

            GET10:
                case (coin)
                    2'b01:     st_next = GET15 ;
                    2'b10:     st_next = IDLE ;
                    default:   st_next = GET10 ;
                endcase
            GET15:
                case (coin)
                    2'b01,2'b10:
                               st_next = IDLE ;
                    default:   st_next = GET15 ;
                endcase
            default:  st_next = IDLE ;
        endcase
    end

    //第三段状态机，时序逻辑 非阻塞赋值
	always @(posedge clk or negedge rstn) begin
		if (!rstn) begin
            change_r <= 2'b0 ;
            sell_r   <= 1'b0 ;			
		end
		else begin
			case (st_cur)
				IDLE:
					begin
						change_r <= 2'b0 ;
						sell_r   <= 1'b0 ;
					end
				GET05:
					begin
						change_r <= 2'b0 ;
						sell_r   <= 1'b0 ;
					end
				GET10:
					begin
						if (coin ==2'd2) begin
							change_r <= 2'b0 ;
							sell_r   <= 1'b1 ;	
						end
						else begin
							change_r <= 2'b0 ;
							sell_r   <= 1'b0 ;
						end
					end
				GET15:
					begin
						if (coin ==2'h1) begin
							change_r <= 2'b0 ;
							sell_r   <= 1'b1 ;
						end
						else if (coin == 2'h2) begin
							change_r <= 2'b1 ;
							sell_r   <= 1'b1 ;
						end
						else begin
							change_r <= 2'b0 ;
							sell_r   <= 1'b0 ;
						end
					end
				default:
					begin
						change_r <= 2'b0 ;
						sell_r   <= 1'b0 ;
					end
			endcase
		end
	end

    assign  sell = sell_r ;
    assign  change = change_r ;

endmodule

testbench 设计如下。仿真中模拟了 4 种情景，分别是：

case1 对应连续输入 4 个 5 角硬币；case2 对应 1 元 - 5 角 - 1 元的投币顺序；case3 对应 5 角 - 1 元 - 5 角的投币顺序；case4 对应连续 3 个 5 角然后一个 1 元的投币顺序。

实例

`timescale 1ns/1ps
module test ;
    reg          clk;
    reg          rstn ;
    reg [1:0]    coin ;
    wire [1:0]   change ;
    wire         sell ;

    //clock generating
    parameter    CYCLE_200MHz = 10 ; 
    always begin
        clk = 0 ; #(CYCLE_200MHz/2) ;
        clk = 1 ; #(CYCLE_200MHz/2) ;
    end

    //motivation generating
    reg [9:0]    buy_oper ;
    initial begin
        buy_oper  = 'h0 ;
        coin      = 2'h0 ;
        rstn      = 1'b0 ;
        #8 rstn   = 1'b1 ;
        @(negedge clk) ;

        //case(1) 0.5 -> 0.5 -> 0.5 -> 0.5
        #16 ;
        buy_oper  = 10'b00_0101_0101 ;
        repeat(5) begin
            @(negedge clk) ;
            coin      = buy_oper[1:0] ;
            buy_oper  = buy_oper >> 2 ;
        end

        //case(2) 1 -> 0.5 -> 1, taking change
        #16 ;
        buy_oper  = 10'b00_0010_0110 ;
        repeat(5) begin
            @(negedge clk) ;
            coin      = buy_oper[1:0] ;
            buy_oper  = buy_oper >> 2 ;
        end

        //case(3) 0.5 -> 1 -> 0.5
        #16 ;
        buy_oper  = 10'b00_0001_1001 ;
        repeat(5) begin
            @(negedge clk) ;
            coin      = buy_oper[1:0] ;
            buy_oper  = buy_oper >> 2 ;
        end

        //case(4) 0.5 -> 0.5 -> 0.5 -> 1, taking change
        #16 ;
        buy_oper  = 10'b00_1001_0101 ;
        repeat(5) begin
            @(negedge clk) ;
            coin      = buy_oper[1:0] ;
            buy_oper  = buy_oper >> 2 ;
        end
    end

   //(1) mealy state with 3-stage
    vending_machine_p3    u_mealy_p3     (
        .clk              (clk),
        .rstn             (rstn),
        .coin             (coin),
        .change           (change),
        .sell             (sell)
        );

   //simulation finish
   always begin
      #100;
      if ($time >= 10000)  $finish ;
   end

endmodule 

仿真结果如下:

由图可知，代表出货动作的信号 sell 都能在投币完毕后正常的拉高，而代表找零动作的信号 change 也都能根据输入的硬币场景输出正确的是否找零信号。

09ad118b0f604446ba1b9b896699c333.png

 

状态机修改：2 段式

将 3 段式状态机 2、3 段描述合并，其他部分保持不变，状态机就变成了 2 段式描述。

修改部分如下：

实例

reg  [1:0]   change_r ;
reg          sell_r ;
always @(*) begin 
    case(st_cur)
        IDLE: begin
            change_r     = 2'b0 ;
            sell_r       = 1'b0 ;
            case (coin)
                2'b01:     st_next = GET05 ;
                2'b10:     st_next = GET10 ;
                default:   st_next = IDLE ;
            endcase 
        end
        GET05: begin
            change_r     = 2'b0 ;
            sell_r       = 1'b0 ;
            case (coin)
                2'b01:     st_next = GET10 ;
                2'b10:     st_next = GET15 ;
                default:   st_next = GET05 ;
            endcase 
        end

        GET10:
            case (coin)
                2'b01:     begin
                    st_next      = GET15 ;
                    change_r     = 2'b0 ;
                    sell_r       = 1'b0 ;
                end
                2'b10:     begin
                    st_next      = IDLE ;
                    change_r     = 2'b0 ;
                    sell_r       = 1'b1 ;
                end
                default:   begin
                    st_next      = GET10 ;
                    change_r     = 2'b0 ;
                    sell_r       = 1'b0 ;
                end
            endcase 
        GET15:
            case (coin)
                2'b01: begin
                    st_next     = IDLE ;
                    change_r    = 2'b0 ;
                    sell_r      = 1'b1 ;
                end
                2'b10:     begin
                    st_next     = IDLE ;
                    change_r    = 2'b1 ;
                    sell_r      = 1'b1 ;
                end
                default:   begin
                    st_next     = GET15 ;
                    change_r    = 2'b0 ;
                    sell_r      = 1'b0 ;
                end
            endcase
        default:  begin
            st_next     = IDLE ;
            change_r    = 2'b0 ;
            sell_r      = 1'b0 ;
        end

    endcase
end

将上述修改的新模块例化到 3 段式的 testbench 中即可进行仿真，结果如下:

由图可知，出货信号 sell 和 找零信号 change 相对于 3 段式状态机输出提前了一个时钟周期，这是因为输出信号都是阻塞赋值导致的。

如图中红色圆圈部分，输出信号都出现了干扰脉冲，这是因为输入信号都是异步的，而且输出信号是组合逻辑输出，没有时钟驱动。

实际中，如果输入信号都是与时钟同步的，这种干扰脉冲是不会出现的。如果是异步输入信号，首先应当对信号进行同步。

494fa55d50ab4f81919543fe192e2090.png

 

状态机修改：1 段式（慎用）

将 3 段式状态机 1、 2、3 段描述合并，状态机就变成了 1 段式描述。

修改部分如下：

实例

    reg  [1:0]   change_r ;
    reg          sell_r ;
    always @(posedge clk or negedge rstn) begin
        if (!rstn) begin
            st_cur     <= 'b0 ;
            change_r   <= 2'b0 ;
            sell_r     <= 1'b0 ;
        end
        else begin
            case(st_cur)

            IDLE: begin
                change_r  <= 2'b0 ;
                sell_r    <= 1'b0 ;
                case (coin)
                    2'b01:     st_cur <= GET05 ;
                    2'b10:     st_cur <= GET10 ;
                endcase
            end
            GET05: begin
                case (coin)
                    2'b01:     st_cur <= GET10 ;
                    2'b10:     st_cur <= GET15 ;
                endcase
            end

            GET10:
                case (coin)
                    2'b01:     st_cur   <=  GET15 ;
                    2'b10:     begin
                        st_cur   <= IDLE ;
                        sell_r   <= 1'b1 ;
                    end
                endcase

            GET15:
                case (coin)
                    2'b01:     begin
                        st_cur   <= IDLE ;
                        sell_r   <= 1'b1 ;
                    end
                    2'b10:     begin
                        st_cur   <= IDLE ;
                        change_r <= 2'b1 ;
                        sell_r   <= 1'b1 ;
                    end
                endcase

            default:  begin
                  st_cur    <= IDLE ;
            end

            endcase // case (st_cur)
        end 
    end

将上述修改的新模块例化到 3 段式的 testbench 中即可进行仿真，结果如下:

由图可知，输出信号与 3 段式状态机完全一致。

1 段式状态机的缺点就是许多种逻辑糅合在一起，不易后期的维护。当状态机和输出信号较少时，可以尝试此种描述方式。

00bd7ab917b24ee0835c952a6391ea24.png

 

状态机修改：Moore 型

如果使用 Moore 型状态机描述售卖机的工作流程，那么还需要再增加 2 个状态编码，用以描述 Mealy 状态机输出时的输入信号和状态机状态。

3 段式 Moore 型状态机描述的自动售卖机 Verilog 代码如下：

实例

module  vending_machine_moore    (
    input           clk ,
    input           rstn ,
    input [1:0]     coin ,     

    output [1:0]    change ,
    output          sell    
    );

    parameter            IDLE   = 3'd0 ;
    parameter            GET05  = 3'd1 ;
    parameter            GET10  = 3'd2 ;
    parameter            GET15  = 3'd3 ;

    parameter            GET20  = 3'd4 ;
    parameter            GET25  = 3'd5 ;

    reg [2:0]            st_next ;
    reg [2:0]            st_cur ;

    //(1) state transfer
    always @(posedge clk or negedge rstn) begin
        if (!rstn) begin
            st_cur      <= 'b0 ;
        end
        else begin
            st_cur      <= st_next ;
        end
    end

    always @(*) begin //all case items need to be displayed completely
        case(st_cur)
            IDLE:
                case (coin)
                    2'b01:     st_next = GET05 ;
                    2'b10:     st_next = GET10 ;
                    default:   st_next = IDLE ;
                endcase
            GET05:
                case (coin)
                    2'b01:     st_next = GET10 ;
                    2'b10:     st_next = GET15 ;
                    default:   st_next = GET05 ;
                endcase

            GET10:
                case (coin)
                    2'b01:     st_next = GET15 ;
                    2'b10:     st_next = GET20 ;
                    default:   st_next = GET10 ;
                endcase
            GET15:
                case (coin)
                    2'b01:     st_next = GET20 ;
                    2'b10:     st_next = GET25 ;
                    default:   st_next = GET15 ;
                endcase
            GET20:         st_next = IDLE ;
            GET25:         st_next = IDLE ;
            default:       st_next = IDLE ;
        endcase
    end 

    reg  [1:0]   change_r ;
    reg          sell_r ;
    always @(posedge clk or negedge rstn) begin
        if (!rstn) begin
            change_r       <= 2'b0 ;
            sell_r         <= 1'b0 ;
        end
        else if (st_cur == GET20 ) begin
            sell_r         <= 1'b1 ;
        end
        else if (st_cur == GET25) begin
            change_r       <= 2'b1 ;
            sell_r         <= 1'b1 ;
        end
        else begin
            change_r       <= 2'b0 ;
            sell_r         <= 1'b0 ;
        end
    end
    assign       sell    = sell_r ;
    assign       change  = change_r ;

endmodule

将上述修改的 Moore 状态机例化到 3 段式的 testbench 中即可进行仿真，结果如下:

由图可知，输出信号与 Mealy 型 3 段式状态机相比延迟了一个时钟周期，这是因为进入到新增加的编码状态机时需要一个时钟周期的时延。此时，输出再用非阻塞赋值就会导致最终的输出信号延迟一个时钟周期。这也属于 Moore 型状态机的特点。

6fa9cb1dd11947fda6142b40818fc4f4.png

 

输出信号赋值时，用阻塞赋值，则可以提前一个时钟周期。

输出逻辑修改如下。

实例

    reg  [1:0]   change_r ;
    reg          sell_r ;
    always @(*) begin
        change_r  = 'b0 ;
        sell_r    = 'b0 ; //not list all condition, initializing them
        if (st_cur == GET20 ) begin
            sell_r         = 1'b1 ;
        end
        else if (st_cur == GET25) begin
            change_r       = 2'b1 ;
            sell_r         = 1'b1 ;
        end
    end

输出信号阻塞赋值的仿真结果如下:

由图可知，输出信号已经和 3 段式 Mealy 型状态机一致。

 

bf44371e24ea49bd8ce54a04692c768d.png

 

 

Linest-5
关注
  • 19
    点赞
  • 踩
  • 107
    收藏
    觉得还不错? 一键收藏
  • 打赏
    打赏
  • 3
    评论
专栏目录
FPGA设计之 使用Mealy状态机 设计序列检测器“101001”
02-16
PGA设计之 使用Mealy状态机 设计序列检测器“101001”资源包括 代码和仿真以及状态转移图的Visio原...具体的说明 请参考本人博客 《使用Moore状态机和Mealy状态机设计序列检测器 II》 ，详细说明了该资源的具体内容。
FPGA设计之 使用Moore状态机 设计序列检测器“101001”
02-16
FPGA设计之 使用Moore状态机 设计序列检测器 。该序列检测器将检测序列“101001”，当检测到该序列时...具体的说明 请参考本人博客 《使用Moore状态机和Mealy状态机设计序列检测器 I》 ，详细说明了该资源的具体内容。
verilog中一文搞懂有限状态机（FSM)Mealy和Moore状态机（及一段式，二段式，三段式）
weixin_42664351的博客
05-27 6868
testbenchverilog示例 verilog示例 module adder( clk,rst,q_out,k ) input clk,rst,k; out q_out; localparam S1 = 0, S2=1, S3=2; reg[1:0] state, nextstate; always @(posedge clk or posedge rst) begin if
状态机设计
apple_53311083的博客
08-06 1198
有限状态机设计，Moore型与Mealy型的区别，序列检测器设计
Verilog基础语法——状态机（类型、写法、状态编码方式）
最新发布
qq_42224089的博客
04-30 1811
在FPGA设计过程，经常会设计状态机用于控制整个硬件电路的工作进程，也称为有限状态机（Finite State Machine，FSM）。本文中对状态机的类型、写法以及状态编码方式进行介绍。
使用Moore状态机和Mealy状态机设计序列检测器 I
qq_34895681的博客
02-16 833
有限状态机（FSM）是时序电路设计中经常用到的一种方式，尤其适用于设计数字系统的控制模块，其配合Verilog的case语句尅很好的描述基于状态机的设计。根据输出信号的产生方法的不同，可以将状态机分为 Mealy型和Moore型。简单的来说，Mealy型的输出跟当前的状态以及当前的输入是有关的，而Moore型的输出只跟当前的状态有关系。即 当Moore型的状态机输入有变化时，需要等到时钟的到来，才会使Moore型状态机的输出变化，依赖于时钟的同步。
设计模式-状态机模式
zbbzb的博客
02-18 2156
设计模式-状态机
三段式状态机（附带testbench）
qq_44765998的博客
09-08 1214
三段式状态机 module state_machine ( input reset_p, input clk_10k, input flag_p, input [7:0]data, output out1 ); reg [1:0]cr_state; reg [1:0]nx_state; reg [2:0]count; reg temp_out1; assign out1=temp_out1; parameter IDLE = 2'b00,START = 2'b01,WRITE = 2'b10,WRITEEN
设计模式 状态机
baiiu
02-19 1201
本文梳理状态机概念，在实操中状态机和类似，只是被封装起来，可以很方便的实现状态初始化和状态转换。
verilog经典三段式状态机设计实例1
08-08
endmodule Mealy型verilog源代码：FSM实现10010串的检测Mealy状态转移图module mealyfsm(clk,rst,a,z);
实验八状态机逻辑电路设计
11-06
例如，电梯控制系统可以看作是一个状态机设计的例子，通过将电梯运行的各个阶段（如在一楼、二楼等）分解为多个状态，然后根据这些状态决定电梯的下一步动作。 实验步骤通常包括设计特定的逻辑电路，例如序列检测器...
Moore mealy 状态机比对
06-18
Moore mealy 状态机比对Moore mealy 状态机比对Moore mealy 状态机比对Moore mealy 状态机比对Moore mealy 状态机比对Moore mealy 状态机比对Moore mealy 状态机比对Moore mealy 状态机比对
有限状态机的VHDL优化设计
03-04
1．引言当前以硬件描述语言为工具、逻辑器件为载体的系统设计越来越广泛。在设计中，状态机是最典型、应用最...状态机可以分为Moore型和Mealy型两种基本类型。设计时采用哪种方式的状态机要根据设计的具体情况决定，输
吃透Chisel语言.28.Chisel进阶之有限状态机（二）——Mealy状态机及与Moore状态机的对比
github-3rr0r的博客
07-27 2022
上一篇文章我们介绍了基本有限状态机（FSM），即Moore机，对应的是输出只和当前状态有关的有限状态机，这一篇我们则学习输出依赖于输入的状态机，即Mealy有限状态机，通过上升沿检测的例子来阐明相关特性，进一步比较Moore机和Mealy机的区别。...
状态机(Moore and Mealy)
qq_42107624的博客
09-25 2264
1、Moore状态机：仅取决于当前状态 设计高速电路时，使得输出与时钟几乎同步，即将状态变量直接用作输出，其输出组合逻辑部分只有连线。 2、Mealy状态机：取决于当前状态和输入 moore完全描述状态转移图会比mealy机多一个状态 在verilog代码中就是，moore机的最后输出逻辑只判断state，mealy机的输出逻辑中判断c_state && input 通过两种方式检测1101，不考虑重叠检测 Moore //Moore ...
状态机的设计（Verilog）
qq_33155311的博客
07-13 1549
文章目录 #状态机的基本概念 #状态机写法 一
服务端指南 | 状态机设计
weixin_34128839的博客
11-01 223
原文地址：服务端指南 | 状态机设计博客地址：blog.720ui.com/ 状态机中，每个状态有着相应的行为，随着行为的触发来切换状态。其中一种做法是使用二维数组实现状态机机制，其中横坐标表示行为，纵坐标表示状态，具体的数值则表示当前的状态。 我们以登录场景设计一个状态机。 这时，我们设计一张状态机表。 那么，此时它的二维数组，如下所示。 此外，我们也可以通过状态模式实现一个状态机。状...
【 FPGA 】状态机的模型之Mealy型状态机
Reborn Lee
11-29 6465
上篇博文讲了：Moore型状态机，这篇博文和上篇博文思路一致，如果读懂了上篇博文，这篇博文就很容易理解了。 如果一个状态机的输出是由现态和输入共同决定的，那么它就是一个Mealy型的状态机。而按照驱动输出的数字电路特性，又将Mealy型状态机细分为Mealy 1型、Mealy 2型、Mealy 3型，详细介绍如下： （1）Mealy 1型 Mealy 1型状态机的原理框图如下图1所示： ...
moore&mealy状态机区分（附例子&代码）&三段式描述方式
热门推荐
筱羊冰冰
12-21 1万+
在状态机部分，moore和mealy也算是老生常谈了吧。 什么是状态？ 说白了就是通过时钟信号不断改变当前的状态，可能是根据输入的数据，也可能是自身发生改变（比如一些计时器），所以少不了触发器，虽然我们有功能十分多的JK，有RS，但是我们一般采用的触发器类型都是D触发器。 状态机的设计 实际电路的设计和verilog设计还不大相同。因为verilog好歹还不是那么底层，不需要自己进行搭线（除非采用结构化描述），也就是我们可以省略一些步骤。 好了么，基本上省了很多了，只需要将状态找出来，进行分配，然后给出
状态机二段式和三段式
08-18
状态机二段式和三段式是两种不同的状态机设计模式。 状态机二段式（Two-Level State Machine）是一种常见的状态机设计模式，它将状态机分为两个层次：顶层和底层。顶层状态机负责处理高级的控制逻辑，而底层状态机负责处理底层的具体操作。底层状态机可以看作是顶层状态机的子状态机，它们之间存在一种层次关系。底层状态机可以在顶层状态机的不同状态之间进行切换，从而实现更细粒度的状态控制。 状态机三段式（Three-Level State Machine）是在状态机二段式的基础上进一步扩展而来的设计模式。它将状态机分为三个层次：顶层、中间层和底层。中间层状态机负责处理一些中间层的逻辑，比如状态转换的条件判断、数据处理等。顶层状态机可以根据中间层状态机的状态进行相应的切换，而中间层状态机则可以根据底层状态机的状态进行相应的切换。通过引入中间层状态机，可以进一步提高状态机的灵活性和可扩展性。 总而言之，状态机二段式和三段式是两种不同的状态机设计模式，它们在状态机的层次结构和状态切换方式上有所不同，可以根据具体需求选择适合的设计模式来实现状态控制。

“相关推荐”对你有帮助么？

  • 非常没帮助
  • 没帮助
  • 一般
  • 有帮助
  • 非常有帮助
提交
评论 3
添加红包

请填写红包祝福语或标题

个

红包个数最小为10个

元

红包金额最低5元

当前余额3.43元 前往充值 >
需支付：10.00元
成就一亿技术人!
领取后你会自动成为博主和红包主的粉丝 规则
hope_wisdom
发出的红包

打赏作者

Linest-5

你的鼓励将是我创作的最大动力

¥1 ¥2 ¥4 ¥6 ¥10 ¥20
扫码支付：¥1
获取中
扫码支付

您的余额不足，请更换扫码支付或充值

打赏作者

实付元
使用余额支付
点击重新获取
扫码支付
钱包余额 0

抵扣说明：

1.余额是钱包充值的虚拟货币，按照1:1的比例进行支付金额的抵扣。
2.余额无法直接购买下载，可以购买VIP、付费专栏及课程。

余额充值