高光反射Phong光照模型

本文借鉴《Unity Shader入门精要》，算是对自己学习的总结，也希望分享下所学知识~~

高光反射是一种经验模型，并不完全符合真实世界中的高光反射现象。
先根据表面法线、视角方向、光源方向计算出反射方向。
通过 Phong 模型来计算高光反射的部分。
一般都用逐像素，得到更平滑的高光效果。

公式：

高光反射光线强度 = 入射光线颜色 * 高光反射颜色 * max( 0, 视角方向 · 反射方向 ) ^ 高光反光度

case 逐顶点：

Shader "SpecularVertexLevel"
{
	Properties
	{
		_Diffuse("Diffuse", Color) = (1,1,1,1)//漫反射颜色
		_Specular("Specular", Color) = (1,1,1,1)//高光颜色
		_Gloss("Gloss", Range(1,256)) = 5//反光度
	}
	SubShader
	{
		Tags { "RenderType"="Opaque" }
		LOD 100

		Pass
		{
			CGPROGRAM
			#pragma vertex vert
			#pragma fragment frag
			#include "UnityCG.cginc"
			#include "Lighting.cginc"

			fixed4 _Diffuse;
			fixed4 _Specular;
			float _Gloss;

			struct v2f
			{
				float4 vertex : SV_POSITION;
				fixed3 color: Color;
			};

			v2f vert (appdata_base v)// appdata_base 内置结构
			{
				v2f o;
				o.vertex = UnityObjectToClipPos(v.vertex);
				fixed3 ambient = UNITY_LIGHTMODEL_AMBIENT.xyz;

				fixed3 worldNormal = UnityObjectToWorldNormal(v.normal);
				fixed3 worldPos = mul(unity_ObjectToWorld, v.vertex);
				fixed3 worldLight = UnityWorldSpaceLightDir(worldPos);//内置函数：从世界空间位置计算世界空间光的方向
				fixed3 diffuse = _LightColor0.rgb * _Diffuse.rgb * max(0, dot(worldNormal,worldLight));

				fixed3 reflectDir = normalize( reflect(-worldLight,worldNormal) );//计算反射方向，reflect 函数的入射方向要求由光源指向交点处，所以取反
				fixed3 viewDir = normalize(UnityWorldSpaceViewDir(worldPos));//内置函数：从对象空间位置计算世界空间视图方向
				fixed3 specular = _LightColor0.rgb * _Specular.rgb * pow(max(0,dot(reflectDir,viewDir)),_Gloss);

				o.color = diffuse + ambient + specular;
				return o;
			}
			
			fixed4 frag (v2f i) : SV_Target
			{
				return fixed4(i.color, 1);
			}
			ENDCG
		}
	}
	FallBack "Diffuse"
}

case 逐像素：

struct v2f
{
	float4 vertex : SV_POSITION;
	fixed3 worldNormal: TEXCOORD0;
	float3 worldPos: TEXCOORD1;
};
v2f vert (appdata_base v)
{
	v2f o;
	o.vertex = UnityObjectToClipPos(v.vertex);
	fixed3 worldNormal = UnityObjectToWorldNormal( v.normal);
	o.worldNormal = worldNormal;//计算世界空间下法线方向给片元着色器
	o.worldPos =  mul(unity_ObjectToWorld, v.vertex);//计算世界空间下顶点坐标给片元着色器
	return o;
}
fixed4 frag (v2f i) : SV_Target
{
	fixed3 ambient = UNITY_LIGHTMODEL_AMBIENT.xyz;

	fixed3 worldLightDir = UnityWorldSpaceLightDir(i.worldPos);
	fixed3 diffuse = _LightColor0.rgb * _Diffuse.rgb * max(0,dot(worldLightDir,i.worldNormal));

	fixed3 reflectDir = normalize(reflect(-worldLightDir,i.worldNormal));
	fixed3 viewDir = normalize(UnityWorldSpaceViewDir(i.worldPos));
	fixed3 specular = _LightColor0.rgb * _Specular.rgb * pow(saturate(dot(reflectDir,viewDir)),_Gloss);
	
	fixed3 color = ambient + diffuse + specular;
	return fixed4(color, 1);
}