UVM中打印信息的控制

原文链接：https://www.coolcou.com/uvm-tutorials/uvm-print-information-control.html

设置打印信息的冗余度阈值

UVM通过冗余度级别的设置提高了仿真日志的可读性。在打印信息之前，UVM会比较要显示信息的冗余度级别与默认的冗余度阈值，如果小于等于阈值，就会显示，否则不会显示。默认的冗余度阈值是UVM_MEDIUM，所有低于等于UVM_MEDIUM（如UVM_ LOW）的信息都会被打印出来。

可以通过get_report_verbosity_level函数得到某个component的冗余度阈值：

virtual function void connect_phase(uvm_phase phase);
  $display("env.i_agt.drv's verbosity level is %0d", env.i_agt.drv.get_report_verbosity_level());
endfunction

这个函数得到的是一个整数，它代表的含义如下所示：

typedef enum
{
  UVM_NONE   = 0,
  UVM_LOW    = 100,
  UVM_MEDIUM = 200,
  UVM_HIGH   = 300,
  UVM_FULL   = 400,
  UVM_DEBUG  = 500
} uvm_verbosity;

UVM提供set_report_verbosity_level函数来设置某个特定component的默认冗余度阈值。在base_test中将driver的冗余度阈值设置为UVM_HIGH（UVM_LOW、UVM_ MEDIUM、UVM_HIGH的信息都会被打印）代码为：

//文件：src/ch3/section3.4/3.4.1/base_test.sv
virtual function void connect_phase(uvm_phase phase);
  env.i_agt.drv.set_report_verbosity_level(UVM_HIGH);
…
endfunction

由于需要牵扯到层次引用，所以需要在connect_phase及以后的phase才能调用这个函数。如果不牵扯到任何层次引用，如设置当前component的冗余度阈值，那么可以在connect_phase之前调用。

set_report_verbosity_level只对某个特定的component起作用。UVM同样提供递归的设置函数set_report_verbosity_level_hier，如把env.i_agt及其下所有的component的冗余度阈值设置为UVM_HIGH的代码为：

env.i_agt.set_report_verbosity_level_hier(UVM_HIGH);

set_report_verbosity_level会对某个component内所有的uvm_info宏显示的信息产生影响。如果这些宏在调用时使用了不同的ID：

set_report_verbosity_level会对某个component内所有的uvm_info宏显示的信息产生影响。如果这些宏在调用时使用了不同的ID：

uvm_info("ID1", "ID1 INFO", UVM_HIGH)
uvm_info("ID2", "ID2 INFO", UVM_HIGH)

那么可以使用set_report_id_verbosity函数来区分不同的ID的冗余度阈值：

env.i_agt.drv.set_report_id_verbosity("ID1", UVM_HIGH);

经过上述设置后“ID1 INFO”会显示，但是“ID2 INFO”不会显示。

这个函数同样有其相应的递归调用函数，其调用方式为：

env.i_agt.set_report_id_verbosity_hier("ID1", UVM_HIGH);

除了在代码中设置外，UVM支持在命令行中设置冗余度阈值：

<sim command> +UVM_VERBOSITY=UVM_HIGH
或者：
<sim command> +UVM_VERBOSITY=HIGH

这两个命令行参数是等价的，即可以把冗余度级别的前缀“UVM_”省略。

上述的命令行参数会把整个验证平台的冗余度阈值设置为UVM_HIGH。它几乎相当于是在base_test中调用set_report_verbosity_level_hier函数，把base_test及以下所有component的冗余度级别设置为UVM_HIGH：

set_report_verbosity_level_hier(UVM_HIGH)

对不同的component设置不同的冗余度阈值非常有用。在芯片级别验证时，重用了不同模块（block）的env。由于个人习惯的不同，每个人对信息冗余度的容忍度也不同，有些人把所有信息设置为UVM_MEDIUM，也有另外一些人喜欢把所有的信息都设置为UVM_ HIGH。通过设置不同env的冗余度级别，可以更好地控制整个芯片验证环境输出信息的质量。

重载打印信息的严重性

重载是深入到UVM骨子里的一个特性。UVM默认有四种信息严重性：UVM_INFO、UVM_WARNING、UVM_ERROR、UVM_FATAL。这四种严重性可以互相重载。如果要把driver中所有的UVM_WARNING显示为UVM_ERROR，可以使用如下的函数：

//文件：src/ch3/section3.4/3.4.2/base_test.sv
virtual function void connect_phase(uvm_phase phase);
    env.i_agt.drv.set_report_severity_override(UVM_WARNING, UVM_ERROR);
    //env.i_agt.drv.set_report_severity_id_override(UVM_WARNING, "my_driver", UVM_ERROR);
endfunction

假如在my_driver中有如下语句：

//文件：src/ch3/section3.4/3.4.2/my_driver.sv
uvm_warning("my_driver", "this information is warning, but prints as UVM_ERROR")

如果不加任何设置，那么输出应该是：

UVM_WARNING my_driver.sv(29) @ 1100000: uvm_test_top.env.i_agt.drv [my_driver]
this information is warning, but prints as UVM_ERROR

但是经过代码清单的设置后，输出变为：

UVM_ERROR my_driver.sv(29) @ 1100000: uvm_test_top.env.i_agt.drv [my_driver]
this information is warning, but prints as UVM_ERROR

重载严重性可以只针对某个component内的某个特定的ID起作用：

env.i_agt.drv.set_report_severity_id_override(UVM_WARNING, "my_driver", UVM_ERROR);

与设置冗余度不同，UVM不提供递归的严重性重载函数。严重性重载用的较少，一般的只会对某个component内使用，不会递归的使用。

重载严重性也可以在命令行中实现，其调用方式为：

<sim command> +uvm_set_severity=<comp>,<id>,<current severity>,<new severity>

如代码清单可以使用如下的命令行参数代替：

<sim command> +uvm_set_severity="uvm_test_top.env.i_agt.drv,my_driver,UVM_WARNING,UVM_ERROR"

若要设置所有的ID，可以在id处使用_ALL_：

<sim command> +uvm_set_severity="uvm_test_top.env.i_agt.drv,_ALL_,UVM_WARNING,UVM_ERROR"

UVM_ERROR到达一定数量结束仿真

当uvm_fatal出现时，表示出现了致命错误，仿真会马上停止。UVM同样支持UVM_ ERROR达到一定数量时结束仿真。这个功能非常有用。对于某个测试用例，如果出现了大量的UVM_ERROR，根据这些错误已经可以确定bug所在了，再继续仿真下去意义已经不大，此时就可以结束仿真，而不必等到所有的objection被撤销。

实现这个功能的是set_report_max_quit_count函数，其调用方式为：

//文件：src/ch3/section3.4/3.4.3/base_test.sv
function void base_test::build_phase(uvm_phase phase);
   super.build_phase(phase);
   env  =  my_env::type_id::create("env", this);
   set_report_max_quit_count(5);
endfunction

上述代码把退出阈值设置为5。当出现5个UVM_ERROR时，会自动退出，并显示如下的信息：

# --- UVM Report Summary ---
#
# Quit count reached!
# Quit count :     5 of     5

在测试用例中的设置方式与base_test中类似。如果测试用例与base_test中同时设置了，则以测试用例中的设置为准。此外，除了在build_phase之外，在其他phase设置也是可以的。

与set_max_quit_count相对应的是get_max_quit_count，可以用于查询当前的退出阈值。如果返回值为0则表示无论出现多少个UVM_ERROR都不会退出仿真：

function int get_max_quit_count();

除了在代码中使用set_max_quit_count设置外，还可以在命令行中设置退出阈值：

<sim command> +UVM_MAX_QUIT_COUNT=6,NO

其中第一个参数6表示退出阈值，而第二个参数NO表示此值是不可以被后面的设置语句重载，其值还可以是YES。

设置计数的目标

当UVM_ERROR达到一定数量时，可以自动退出仿真。在计数当中，是不包含UVM_WARNING的。可以通过设置set_report_severity_action函数来把UVM_ WARNING加入计数目标：

//文件：src/ch3/section3.4/3.4.4/base_test.sv
virtual function void connect_phase(uvm_phase phase);
   set_report_max_quit_count(5);
   env.i_agt.drv.set_report_severity_action(UVM_WARNING, UVM_DISPLAY|UVM_COUNT);
…
endfunction

通过上述代码，可以把env.i_agt.drv的UVM_WARNING加入到计数目标中。set_ report_severity_action有相应的递归调用方式：

env.i_agt.set_report_severity_action_hier(UVM_WARNING, UVM_DISPLAY| UVM_COUNT);

上述代码把env.i_agt及其下所有结点的UVM_WARNING加入到计数目标中。

set_report_severity_action及set_report_severity_action_hier的第一个参数除了是UVM_WARNING外，还可以是UVM_INFO，UVM_ERROR。在默认情况下，UVM_ ERROR已经加入了统计计数。如果要把其从统计计数目标中移除，可以：

env.i_agt.drv.set_report_severity_action(UVM_ERROR, UVM_DISPLAY);

除了针对严重性进行计数外，还可以对某个特定的ID进行计数：

env.i_agt.drv.set_report_id_action("my_drv", UVM_DISPLAY| UVM_COUNT);

上述代码把ID为my_drv的所有信息加入到计数中，无论是UVM_INFO，还是UVM_ WARNING或者是UVM_ERROR、UVM_FATAL。

set_report_id_action同样有其递归调用方式：

env.i_agt.set_report_id_action_hier("my_drv", UVM_DISPLAY| UVM_COUNT);

除了分别对严重性和ID进行设置外，UVM还支持把它们联合起来进行设置：