菲涅尔效果

游戏中为了体现人物处于某种特殊状态（如狂怒，矍铄等），可以在模型的表面在一些顶点出增加自己设定的颜色，如下图所示

菲涅尔效果的意义是：当光从一种具有折射率为的介质向另一种具有折射率为的介质传播时，在两者的交界处（通常称作界面）可能会同时发生光的反射和折射。菲涅尔方程描述了不同光波分量被折射和反射的情况。

shader如下：

Shader "Custom/ShipShader" {
    Properties
    {
        _MainTex ("Base 2d", 2D)="white"{}
        _MainColor("main color", Color)=(1,1,1,1)

        _FlowSpeedX("streamLightX", Range(0, 20))=0 
        _FlowSpeedY("streamLightY",Range(0, 20)) = 0
        _FlowMap("stream map", 2D)="white"{}
        _FlowPower("flow power ", Range(0.1, 10))=2

        _RefCubeMap("reflect map", Cube)=""{}
        _RefAmount("reflect amount", Float)=1 

        _RimPower("rim power ", Range(0.1, 10))=2
        _RimColor("rim color", Color)=(1,1,1,1)
    }

    SubShader
    {
        pass
        {
            Tags{  "RenderType"="Opaque"}

            CGPROGRAM 
            #pragma vertex vert 
            #pragma fragment frag 
            //#include "Lighting.cginc"
            #include "UnityCG.cginc"

            sampler2D _MainTex;
            float4 _MainTex_ST;

            float4 _MainColor;

            half _FlowSpeedX;
            half _FlowSpeedY;
            half _FlowPower;

            sampler2D _FlowMap;
            samplerCUBE _RefCubeMap;
            half _RefAmount;

            half _RimPower;
            float4 _RimColor;

            struct appdata 
            {
                float4 vertex:POSITION;
                float4 texcoord:TEXCOORD0;
                float3 normal:NORMAL;
            };

            struct v2f 
            {
                float4 pos:POSITION;
                float4 uv:TEXCOORD0;
                float3 normal:NORMAL;   
                float3 viewDir:TEXCOORD1;
                float3 lightDir:TEXCOORD2;                          
            };

            v2f vert(appdata i)
            {
                v2f v;
                v.pos = mul(UNITY_MATRIX_MVP, i.vertex);
                v.uv.xy = TRANSFORM_TEX(i.texcoord, _MainTex);

                //流光贴图UV
                _FlowSpeedX *= _Time;
                _FlowSpeedY *= _Time;
                v.uv.z = v.uv.x + _FlowSpeedX;
                v.uv.w = v.uv.y + _FlowSpeedY;

                v.normal = mul((float3x3)_World2Object, i.normal);

                v.viewDir = WorldSpaceViewDir(i.vertex);
                v.lightDir = WorldSpaceLightDir(i.vertex);
                return v;
            }

            float4 frag(v2f v):COLOR
            {
                float4 col = tex2D(_MainTex, v.uv.xy);

                //给贴图取灰度，用作反射通道
                half mask = col.r * 0.299 + col.g * 0.587 + 0.144 * col.b;

                col.rgb *= _MainColor.rgb;

                fixed flow = tex2D(_FlowMap, v.uv.zw).r;

                //ref = worldView - 2* dot(worldView,n) ===> refect(w,n)
                float3 refl = reflect(-v.viewDir ,v.normal);

                //环境光反射
                float3 emi = texCUBE(_RefCubeMap, refl).rgb * mask * _RefAmount;

                //菲涅尔用作边缘流光强度
                float rim = 1 - saturate(dot(normalize(v.viewDir), v.normal));
                rim = pow(rim, _RimPower);

                emi += flow * rim * _RimColor.xyz * _FlowPower;
                col.x += emi.x;
                col.y += emi.y;
                col.z += emi.z;
                return col;
            }


            ENDCG
        }

    }
    //FallBack "Diffuse"
}