Unity Shader特效：遮挡显示

写于2017-6-7，转载请注明

以下是正文

………………………………………………………………………………………………

先上效果：

 

这是游戏中常用的特效之一。原以为挺简单的，没想到几乎折腾了一早上，掉进了一些坑里。主要是ZWrite与ZTest的问题，何时开启，何时关闭，何时用何参数，还有Pass的先后顺序等等……

代码如下，一切尽在不言中：

Shader "Custom/ShowOcclusion" {
        Properties {
            _Color ("Color", Color) = (1,1,1,1)
            _MainTex ("Albedo (RGB)", 2D) = "white" {}
            _Glossiness ("Smoothness", Range(0,1)) = 0.5
            _Metallic ("Metallic", Range(0,1)) = 0.0
            _OcclusionColor("OcclusionColor",Color)=(0.5,1,0.5,1)
        }
        SubShader 
        {
            Tags { "RenderType"="Opaque" }
            LOD 200
            //此Pass务必放在前面
        Pass
        {
            ZTest Greater
            ZWrite Off//重要，关闭ZWrite后，后渲染的会覆盖此Pass

            CGPROGRAM
            #pragma vertex vert 
            #pragma fragment frag
            fixed4 _OcclusionColor;
            float4 vert(float4 v : POSITION) : SV_POSITION {
                return mul(UNITY_MATRIX_MVP, v);
            }
            fixed4 frag() : SV_Target{
                return _OcclusionColor;
            }
            ENDCG
        }

        ZTest LEqual
        CGPROGRAM
        // Physically based Standard lighting model, and enable shadows on all light types
        #pragma surface surf Standard fullforwardshadows
        // Use shader model 3.0 target, to get nicer looking lighting
        #pragma target 3.0
        struct Input {
            float2 uv_MainTex;
        };
        sampler2D _MainTex;
        half _Glossiness;
        half _Metallic;
        fixed4 _Color;
        void surf (Input IN, inout SurfaceOutputStandard o) {
            // Albedo comes from a texture tinted by color
            fixed4 c = tex2D (_MainTex, IN.uv_MainTex) * _Color;
            o.Albedo = c.rgb;
            // Metallic and smoothness come from slider variables
            o.Metallic = _Metallic;
            o.Smoothness = _Glossiness;
            o.Alpha = c.a;
        }
        ENDCG
    }
    FallBack "Diffuse"
}

 

 
参考文章： 
1、【Unity ImageEffect】一个用于角色遮挡透视轮廓的效果
http://blog.csdn.net/herox25000/article/details/50502096
 2、Unity3D研究院之处理摄像机与角色之间被挡时的局部透明效果
http://www.xuanyusong.com/archives/3466 ;
 3、[UnityShader]渲染队列、ZWrite和ZTest
http://blog.csdn.net/lyh916/article/details/45317571 ;
 4、Unity ZTest 深度测试 & ZWrite 深度写入 
http://www.cnblogs.com/ljx12138/p/5341381.html