CMake4-指令1-1：add_executable【基于特定的源文件（入口源文件），创建可执行文件】

一、普通可执行文件

add_executable(<name> [WIN32] [MACOSX_BUNDLE]
               [EXCLUDE_FROM_ALL]
               [source1] [source2 ...])

该命令将添加一个名为 <name> 的可执行目标，由命令调用中列出的源文件构建。<name> 对应于逻辑目标名称，在项目中必须是全局唯一的。构建的可执行文件的实际文件名基于原生平台的约定构建（例如 <name>.exe 或仅仅是 <name>）。

• name:可执行目标文件的名字，在一个cmake工程中，这个名字必须全局唯一。
• WIN32:用于windows系统下创建一个以WinMain为入口的可执行目标文件（通常入口函数为main），它不是一个控制台应用程序，而是一个GUI应用程序。当WIN32选项使用的时候，可执行目标的 WIN32_EXECUTABLE会被置位ON。
• MACOSX_BUNDLE:用于mac系统或者IOS系统下创建一个GUI可执行应用程序，当MACOSX_BUNDLE选项使用的时候，可执行目标的MACOSX_BUNDLE会被置位ON。
• EXCLUDE_FROM_ALL:用于指定可执行目标是否会被构建，当该选项使用的时候，可执行目标不会被构建。
  [source1] [source2 …]:构建可执行目标文件所需要的源文件。也可以通过target_sources()继续为可执行目标文件添加源文件，要求是在调用target_sources之前，可执行目标文件必须已经通过add_executable或add_library定义了。

默认情况下，可执行文件将在构建树目录中创建，该目录对应于调用命令的源树目录。请参阅 RUNTIME_OUTPUT_DIRECTORY 目标属性的文档以更改此位置。请参阅 OUTPUT_NAME 目标属性的文档以更改最终文件名的 <name> 部分。

• 如果指定了 WIN32，则将在创建的目标上设置 WIN32_EXECUTABLE 属性。
• 如果指定了 MACOSX_BUNDLE，则将在创建的目标上设置相应的属性。
• 如果指定了 EXCLUDE_FROM_ALL，则将在创建的目标上设置相应的属性。

有关定义构建系统属性的更多信息，请参阅 cmake-buildsystem(7) 手册。

• 版本 3.1 新特性：add_executable 的源文件参数可以使用 $<...> 语法的 “生成器表达式”。有关可用表达式的详细信息，请参阅 cmake-generator-expressions(7) 手册。
• 版本 3.11 新特性：如果使用 target_sources() 稍后添加源文件，则可以省略源文件。

一个例子：

 #CMakeLists.txt
 cmake_minimum_required(VERSION 3.10.2)
 project(test)
 
 SET(CMAKE_RUNTIME_OUTPUT_DIRECTORY output) #设置可执行目标文件的输出目录
 
 include_directories(sub)
 add_subdirectory(sub)
 
 add_executable(runtest main.cpp)
 target_sources(runtest test.cpp)

// test.h
#include <string>
void test(std::string str);
 
// test.cpp
#include "test.h"
#include <iostream>
void test(std::string str)
{
    std::cout << "In test: " << str << std::endl;
}
 
// main.cpp
#include "test.h"
int main(int argc, char **argv)
{
    test("hello, world!");
    return 0;  
}

# 执行cmake .;make;./output/runtest后的输出
In test: hello, world!

二、导入的可执行文件

add_executable(<name> IMPORTED [GLOBAL])

将工程外部的可执行目标文件导入进来，不会有任何构建可执行目标文件的动作发生。如果不指定GLOBAL，则可执行目标文件的范围为文件创建的目录及子目录；指定GLOBAL则会将范围扩大到整个工程。IMPORTED选项指定后，属性IMPORTED会被置为TRUE，在工程内构建的可执行目标文件的属性IMPORTED会被置为FALSE。

例如，将外部的git导入到当前工程中：

#CMakeLists.txt
cmake_minimum_required(VERSION 3.10.2)
project(test)
 
set(GIT_EXECUTABLE "/usr/local/bin/git")
add_executable(Git::Git IMPORTED)
set_property(TARGET Git::Git PROPERTY IMPORTED_LOCATION "${GIT_EXECUTABLE}")
get_target_property(git_location Git::Git IMPORTED_LOCATION)
get_target_property(git_imported Git::Git IMPORTED)
message(">>> git location: ${git_location}, ${git_imported}")

# 输出
>>> git location: /usr/local/bin/git, TRUE

三、别名可执行文件

add_executable(<name> ALIAS <目标>)

创建一个别名目标，使得 <name> 可以在后续命令中用于引用 <目标>。<name> 不会作为构建系统中的 make 目标出现。

为可执行目标文件创建一个别名。创建该别名后，可以使用别名进行可执行目标的读、测试操作，但是不能利用别名对可执行目标的修改属性操作。

#CMakeLists.txt
cmake_minimum_required(VERSION 3.10.2)
project(test)
 
SET(CMAKE_RUNTIME_OUTPUT_DIRECTORY output)
 
add_executable(runtest main.cpp)
 
add_executable(test_name ALIAS runtest)
get_target_property(alias_name test_name ALIASED_TARGET)
if(alias_name)
    message(">>> The name test_name is an ALIAS for ${alias_name}")
endif()

# 输出
>>> The name test_name is an ALIAS for runtest

版本更新说明

• 版本 3.11 新特性：ALIAS 可以指向一个 GLOBAL 导入目标。
• 版本 3.18 新特性：ALIAS 可以指向一个非 GLOBAL 导入目标。

ALIAS 目标可以用作读取属性的目标，自定义命令和自定义目标的可执行文件。它们也可以使用常规的 if(TARGET) 子命令进行存在性测试。<name> 不能用于修改 <目标> 的属性，即，它不能用作 set_property(), set_target_properties(), target_link_libraries() 等的参数。ALIAS 目标不能被安装或导出。

---

---

---

Cmake命令之add_executable介绍
add_executable — CMake 3.22.6 Documentation
CMake之add_executable