UnityShader初级篇——BlinnPhong光照模型

1.BlinnPhong光照模型

引入新矢量h：

h = normalize(视角方向+ 光照方向)；

公式：

高光光照 = （光照颜色与强度 * 高光反射系数）* pow(saturate(dot(法线方向，h))，高光范围系数)；

Shader "Unity Shaders Book/Chapter 6/BlinnPhong"
{
	Properties
	{
		_Diffuse ("Diffuse", Color) = (1,1,1,1)
		//控制高光反射的颜色
		_Specular("Specular", Color) = (1,1,1,1)
		//控制高光区域的大小
		_Gloss("Gloss", Range(8.0,256)) = 20
	}
	SubShader
	{
		Pass
		{
		      //指明光照模式
		       Tags {"LightMode"="ForwardBase"}
		       
			CGPROGRAM
			#pragma vertex vert
			#pragma fragment frag
			//包含引用的内置文件
			#include "Lighting.cginc"

			//声明properties中定义的属性
			fixed4 _Diffuse;
			fixed4 _Specular;
			float _Gloss;

			//定义输入与输出的结构体
			struct a2v
			{
				float4 vertex : POSITION;
				float3 normal : NORMAL;
			};

			struct v2f
			{
				float4 pos : SV_POSITION;
				//存储世界坐标下的法线方向和顶点坐标
				float3 worldNormal : TEXCOORD0;
				float3 worldPos : TEXCOORD1;
			};

			//在顶点着色器中，计算世界坐标下的法线方向和顶点坐标，并传递给片元着色器
			v2f vert (a2v v)
			{
				v2f o;
				//转换顶点坐标到裁剪空间
				o.pos = UnityObjectToClipPos(v.vertex);
				//转换法线坐标到世界空间，直接使用_Object2World转换法线，不能保证转换后法线依然与模型垂直
				o.worldNormal = mul(v.normal, (float3x3)unity_WorldToObject);
				//转换顶点坐标到世界空间
				o.worldPos = mul(unity_ObjectToWorld, v.vertex).xyz;	
				return o;
			}

			//在片元着色器中计算光照模型
			fixed4 frag (v2f i) : SV_Target
			{
				 //获取环境光
				fixed3 ambient = UNITY_LIGHTMODEL_AMBIENT.xyz;

				fixed3 worldNormal = normalize(i.worldNormal);
				fixed3 worldLightDir = normalize(_WorldSpaceLightPos0.xyz);

				//计算漫反射光照
				fixed3 diffuse = _LightColor0.rgb * _Diffuse.rgb * saturate(dot(worldNormal,worldLightDir));

				//获取视角方向 = 摄像机的世界坐标 - 顶点的世界坐标
				fixed3 viewDir = normalize(_WorldSpaceCameraPos.xyz - i.worldPos.xyz);
				//计算新矢量h
				fixed3 halfDir = normalize(viewDir + worldLightDir);
				//计算高光光照
				fixed3 specular = _LightColor0.rgb * _Specular.rgb * pow(saturate(dot(worldNormal,halfDir)),_Gloss);

				return fixed4(ambient + diffuse + specular,1.0);

			}
			ENDCG
		}
	}

	Fallback"Specular"
}