轮廓线——几何实现

本文主要是学习：https://assetstore.unity.com/packages/vfx/shaders/toon-shader-free-21288
从unity asset store中可以下载资源，并且是免费的。里面的轮廓线是几何实现方法。

其他的几种轮廓线实现参考：https://gameinstitute.qq.com/community/detail/114228

下面就来自行实现下其中的代码。

1、写一个shader，用来简单的采样贴图。

Shader "MyShader/RoleBase"
{
	Properties
	{
		_MainTex("Base (RGB)", 2D) = "white"{}
	}

	SubShader
	{
		Tags{"Queue"="Geometry" "RenderType"="Opaque"}
		LOD 100
		Pass
		{
			Name "RoleBase"

			CGPROGRAM
			#pragma vertex vert
			#pragma fragment frag
			#include "UnityCG.cginc"

			struct appdata_t
			{
				float4 vertex : POSITION;
				float2 texcoord : TEXCOORD0;
			};

			struct v2f
			{
				float4 vertex : SV_POSITION;
				half2 uv : TEXCOORD0;
			};

			sampler2D _MainTex;
			float4 _MainTex_ST;

			v2f vert(appdata_t v)
			{
				v2f o;
				o.vertex = UnityObjectToClipPos(v.vertex);
				o.uv = TRANSFORM_TEX(v.texcoord, _MainTex);
				return o;
			}

			fixed4 frag(v2f i) :SV_Target
			{
				fixed4 col = tex2D(_MainTex, i.uv);
				return col;
			}
			ENDCG
		}
	}
}

这样渲染的结果如下：

注意点：
在BaseShader中，我们看到了使用了
Name “RoleBase”
为通道命名了。

这样做的目的是，在写轮廓线的时候，能够复用这个通道。

2、轮廓线
原理：沿着法线的方向增长顶点，然后我们想想，模型沿着法线的方向增长，那么朝向我们的面也要凸出来了，而轮廓在朝着我们的方向上是没有，只是在侧面有。于是我们要开启一个正面剔除：Cull Front。

Shader "MyShader/OutlineShader"
{
	Properties
	{
		_MainTex("Base (RGB)", 2D) = "white"{}
		_OutlineColor("Outline Color", Color) = (0.5,0.5,0.5,1.0)					//10
		_Outline("Outline width", Float) = 0.01									//11
	}

	SubShader
	{
		Tags{"Queue"="Geometry" "RenderType"="Opaque"}
		LOD 100

		UsePass "MyShader/RoleBase/RoleBase"

		Pass
		{
			Cull Front

			CGPROGRAM
			#pragma vertex vert
			#pragma fragment frag
			#include "UnityCG.cginc"

			struct appdata_t
			{
				float4 vertex : POSITION;
				float3 normal : NORMAL;
				float2 texcoord : TEXCOORD0;
			};

			struct v2f
			{
				float4 pos : SV_POSITION;
				half2 texcoord : TEXCOORD0;
			};

		
			fixed _Outline;
			fixed4 _OutlineColor;

			v2f vert(appdata_t v)
			{
				v2f o;
				o.pos = v.vertex;
				o.pos.xyz += normalize(v.normal.xyz) *_Outline*0.01;
				o.pos = UnityObjectToClipPos(o.pos);
				return o;
			}

			fixed4 frag(v2f i) :SV_Target
			{
				return _OutlineColor;
			}
			ENDCG
		}
	}
}

结果如下：

最后的捧上项目：https://gitee.com/yichichunshui/Outline_Geometry_Normal.git