Unity Shader-遮挡处理

简介

 

第三人称游戏,我们经常会遇到相机被场景中的建筑物遮挡的情况。今天,本人就来研究一下相机被遮挡之后的处理。最简单的就是传说中的“鸵鸟法”,假装看不见,在一些游戏里面也有一些玩法设定,或者是本身遮挡较少,影响不大的情况,也可以直接不进行处理。

当然,更好一些的遮挡处理,就是X光的效果。在人物被遮挡的部分会透过遮挡物,用一个其他的颜色渲染出来。《火炬之光》中就使用过这个效果:


类似的,《耻辱2》中的透视效果也是游戏中经常使用的,这种暂且叫其遮挡高亮或者遮挡描边吧,对于刺杀类型的游戏,这种透视技能简直是神技,比如在柱子后面就能瞄见这货:


还有一种对于遮挡的处理,就是遮挡半透,这个在很多游戏里面都有出现,比如《黑魂2》,《奥瑞与黑暗森林》,下面是Ori中的一个遮挡半透的效果动图:


还有一个效果,暂且叫其遮挡溶解吧。这个效果我是在《神界3:原罪》中看到的,说实话,第一次看到这个效果的时候,着实被惊艳到了。


翻箱倒柜找出来这几个游戏,截了一发图,顺道怀念一下。哎呀,一不小心就给自己挖了个超级大的坑。四个效果,下面开始慢慢填坑吧。


 X光效果


先来看一下最为古老的X光效果,所谓X光,就是在被遮挡的部分呈现一个其他的颜色。我们需要获得哪个地方被遮挡了,先复习一下深度测试,渲染队列相关内容。Unity内置了一些渲染队列,并且我们可以自定义一些渲染队列。在同一个渲染队列的情况下,Unity对于不透明物体会按照从前向后的顺序渲染;对于透明物体,会按照从后向前的顺序渲染。比如我们有一个如下的场景:

正常渲染的情况下,首先渲染的是前面遮挡的栅栏,此时深度缓存中有了栅栏的深度值。然后再渲染人模(其实前后无所谓的,因为即使是先渲染人模,再渲染栅栏,遮挡部分深度测试成功也会替代人模的部分,这样会造成OverDraw,所以Unity对于不透明物体一般采用从前向后的顺序),人模被遮挡的部分深度测试失败,颜色不会输出。
下面再来看一下X光效果的流程。首先,还是先渲染栅栏,必须优先保证栅栏的渲染,所以用渲染队列进行控制渲染顺序更加靠谱一点,毕竟按照物体进行的简单深度排序的不一定完全靠谱。下面,设置人模的渲染队列比栅栏靠后一些,人物通过两个Pass渲染,第一个Pass渲染X光的Pass,这个Pass在渲染的时候使用ZTest Greater,在渲染的时候,有遮挡的部分之前的栅栏的深度,而未遮挡的部分由于深度无穷大深度测试不会通过,不显示任何内容,而被遮挡的部分,深度是栅栏的深度,人物在栅栏后,深度大于栅栏,深度测试通过,会将遮挡部分渲染成Pass的输出,而且,这个Pass不能写入深度,因为我们还需要正常画出人物未被遮挡的部分,此时就可以正常的深度测试ZTest LEqual,被遮挡的部分不渲染,只渲染未被遮挡的部分。我们用一个最简单的shader先试一下效果:

[csharp] view plain copy
  1. //X光效果  
  2. //by:puppet_master  
  3. //2017.6.20  
  4.   
  5. Shader "ApcShader/XRayEffect"  
  6. {  
  7.     Properties  
  8.     {  
  9.         _MainTex("Base 2D", 2D) = "white"{}  
  10.     }  
  11.   
  12.     SubShader  
  13.     {  
  14.         Tags{ "Queue" = "Geometry" "RenderType" = "Opaque" }  
  15.           
  16.         //渲染X光效果的Pass  
  17.         Pass  
  18.         {  
  19.             Blend SrcAlpha One  
  20.             ZWrite Off  
  21.             ZTest Greater  
  22.   
  23.             CGPROGRAM  
  24.             #include "Lighting.cginc"  
  25.             struct v2f  
  26.             {  
  27.                 float4 pos : SV_POSITION;  
  28.             };  
  29.   
  30.             v2f vert (appdata_base v)  
  31.             {  
  32.                 v2f o;  
  33.                 o.pos = mul(UNITY_MATRIX_MVP, v.vertex);  
  34.                 return o;  
  35.             }  
  36.   
  37.             fixed4 frag(v2f i) : SV_Target  
  38.             {  
  39.                 return fixed4(1,1,1,0.5);  
  40.             }  
  41.             #pragma vertex vert  
  42.             #pragma fragment frag  
  43.             ENDCG  
  44.         }  
  45.           
  46.         //正常渲染的Pass  
  47.         Pass  
  48.         {  
  49.             ZWrite On  
  50.             CGPROGRAM  
  51.             #include "Lighting.cginc"  
  52.             sampler2D _MainTex;  
  53.             float4 _MainTex_ST;  
  54.   
  55.             struct v2f  
  56.             {  
  57.                 float4 pos : SV_POSITION;  
  58.                 float2 uv : TEXCOORD1;  
  59.             };  
  60.   
  61.             v2f vert(appdata_base v)  
  62.             {  
  63.                 v2f o;  
  64.                 o.pos = mul(UNITY_MATRIX_MVP, v.vertex);  
  65.                 o.uv = TRANSFORM_TEX(v.texcoord, _MainTex);  
  66.                 return o;  
  67.             }  
  68.   
  69.             fixed4 frag(v2f i) : SV_Target  
  70.             {  
  71.                 return tex2D(_MainTex, i.uv);  
  72.             }  
  73.  
  74.             #pragma vertex vert  
  75.             #pragma fragment frag     
  76.             ENDCG  
  77.         }  
  78.     }  
  79.       
  80.     FallBack "Diffuse"  
  81. }  
效果如下:


上图基本实现了X光的效果,不过效果不是很美观,我们将X光的Pass更换一下,使用半透+边缘光的效果进行渲染,代码如下:

[csharp] view plain copy
  1. //X光效果  
  2. //by:puppet_master  
  3. //2017.6.20  
  4.   
  5. Shader "ApcShader/XRayEffect"  
  6. {  
  7.     Properties  
  8.     {  
  9.         _MainTex("Base 2D", 2D) = "white"{}  
  10.         _XRayColor("XRay Color", Color) = (1,1,1,1)  
  11.     }  
  12.   
  13.     SubShader  
  14.     {  
  15.         Tags{ "Queue" = "Geometry+100" "RenderType" = "Opaque" }  
  16.           
  17.         //渲染X光效果的Pass  
  18.         Pass  
  19.         {  
  20.             Blend SrcAlpha One  
  21.             ZWrite Off  
  22.             ZTest Greater  
  23.   
  24.             CGPROGRAM  
  25.             #include "Lighting.cginc"  
  26.             fixed4 _XRayColor;  
  27.             struct v2f  
  28.             {  
  29.                 float4 pos : SV_POSITION;  
  30.                 float3 normal : normal;  
  31.                 float3 viewDir : TEXCOORD0;  
  32.             };  
  33.   
  34.             v2f vert (appdata_base v)  
  35.             {  
  36.                 v2f o;  
  37.                 o.pos = mul(UNITY_MATRIX_MVP, v.vertex);  
  38.                 o.viewDir = ObjSpaceViewDir(v.vertex);  
  39.                 o.normal = v.normal;  
  40.                 return o;  
  41.             }  
  42.   
  43.             fixed4 frag(v2f i) : SV_Target  
  44.             {  
  45.                 float3 normal = normalize(i.normal);  
  46.                 float3 viewDir = normalize(i.viewDir);  
  47.                 float rim = 1 - dot(normal, viewDir);  
  48.                 return _XRayColor * rim;  
  49.             }  
  50.             #pragma vertex vert  
  51.             #pragma fragment frag  
  52.             ENDCG  
  53.         }  
  54.           
  55.         //正常渲染的Pass  
  56.         Pass  
  57.         {  
  58.             ZWrite On  
  59.             CGPROGRAM  
  60.             #include "Lighting.cginc"  
  61.             sampler2D _MainTex;  
  62.             float4 _MainTex_ST;  
  63.   
  64.             struct v2f  
  65.             {  
  66.                 float4 pos : SV_POSITION;  
  67.                 float2 uv : TEXCOORD0;  
  68.             };  
  69.   
  70.             v2f vert(appdata_base v)  
  71.             {  
  72.                 v2f o;  
  73.                 o.pos = mul(UNITY_MATRIX_MVP, v.vertex);  
  74.                 o.uv = TRANSFORM_TEX(v.texcoord, _MainTex);  
  75.                 return o;  
  76.             }  
  77.   
  78.             fixed4 frag(v2f i) : SV_Target  
  79.             {  
  80.                 return tex2D(_MainTex, i.uv);  
  81.             }  
  82.  
  83.             #pragma vertex vert  
  84.             #pragma fragment frag     
  85.             ENDCG  
  86.         }  
  87.     }  
  88.       
  89.     FallBack "Diffuse"  
  90. }  
来一张动图看一下X光的效果:



遮挡描边效果


除了X光效果可以表现遮挡,还有一种后处理也可以达到类似的效果。关于描边的具体实现,可以参考描边效果这篇文章。后处理的描边,是通过额外的相机渲染需要描边的模型到RT上(或者使用Commond Buffer插入渲染事件),得到Mask图进行扣除处理之后,再叠加回原始图像上。描边有个弊端就是后处理的遮挡关系不好处理,但是如果我们要做遮挡处理的效果,弊端就变成了优势。因为即使被描边的对象被其他对象遮挡,由于另外一个相机渲染到RT上时,只会渲染自身,而不会渲染遮挡物,所以Mask图上只会有要描边的对象。下面来炒一发冷饭,掏出我们之前的描边效果的后处理,看一下效果。

不过有一个地方需要注意一下,直接描边的话,在自身看不是很明显,但是如果在遮挡的情况下,只显示一个描边,有一个解决的办法就是开AA。RT默认的没有办法走硬件AA的,跟我们正常工程的设置AA无关,Unity倒是也给我们提供了RT的AA设置(1,2,4,8),but,这个东西的实现原理是超采样,从Profiler里面看的话,不仅仅有我们申请的一张RT,还会出现两张更大(貌似是翻倍的)RT,用于这个效果。所以,在移动平台申请RT的时候,对于是否开AA还是需要慎重考虑一下,一个2048的RT,开了4级别的AA可能会有60M的占用!

下面,我们再稍微加工一下这个描边效果,让它更像《耻辱》游戏里面的这个样子。描边的做法是先渲物体到RT上,然后把RT进行Blur外扩,再与原图相减,最终再叠加回去。我们可以不进行相减这一个操作,直接将RT叠加回去。不过这样的话,人物就是一个大色块了,并不是很好看。我们之前的文章写过CommandBuffer,CmdBuffer是允许我们用任意一个自定义的shader渲染一个物体的,所以可以直接用一个RimLight的shader作为把人物渲染到RT上的prepass shader,其他与做法与描边类似,只是不进行Blur图与原图相减的操作,C#代码如下:
[csharp] view plain copy
  1. /******************************************************************** 
  2.  FileName: OccOutLineEffect.cs 
  3.  Description: 遮挡描边后处理效果 
  4.  Created: 2017/07/20 
  5.  by puppet_master 
  6. *********************************************************************/  
  7. using UnityEngine;  
  8. using System.Collections;  
  9. using UnityEngine.Rendering;  
  10.   
  11. public class OccOutLineEffect : PostEffectBase  
  12. {  
  13.     private RenderTexture renderTexture = null;  
  14.     private CommandBuffer commandBuffer = null;  
  15.     //采样率  
  16.     public float samplerScale = 1;  
  17.     //降采样  
  18.     public int downSample = 1;  
  19.     //迭代次数  
  20.     public int iteration = 2;  
  21.     //描边强度  
  22.     [Range(0.0f, 10.0f)]  
  23.     public float outLineStrength = 3.0f;  
  24.     //目标对象  
  25.     public GameObject targetObject = null;  
  26.   
  27.     void OnEnable()  
  28.     {  
  29.         Renderer[] renderers = targetObject.GetComponentsInChildren<Renderer>();  
  30.         //RT可以设置AA等级,降低锯齿效果  
  31.         if (renderTexture == null)  
  32.             renderTexture = RenderTexture.GetTemporary(Screen.width >> downSample, Screen.height >> downSample);  
  33.         //创建描边prepass的command buffer  
  34.         commandBuffer = new CommandBuffer();  
  35.         commandBuffer.SetRenderTarget(renderTexture);  
  36.         commandBuffer.ClearRenderTarget(truetrue, Color.black);  
  37.         foreach (Renderer r in renderers)  
  38.             commandBuffer.DrawRenderer(r, r.sharedMaterial);  
  39.     }  
  40.   
  41.     void OnDisable()  
  42.     {  
  43.         if (renderTexture)  
  44.         {  
  45.             RenderTexture.ReleaseTemporary(renderTexture);  
  46.             renderTexture = null;  
  47.         }  
  48.         if (commandBuffer != null)  
  49.         {  
  50.             commandBuffer.Release();  
  51.             commandBuffer = null;  
  52.         }  
  53.   
  54.     }  
  55.   
  56.     void OnRenderImage(RenderTexture source, RenderTexture destination)  
  57.     {  
  58.         if (_Material && renderTexture && commandBuffer != null)  
  59.         {  
  60.             //直接通过Graphic执行Command Buffer  
  61.             Graphics.ExecuteCommandBuffer(commandBuffer);  
  62.   
  63.             //对RT进行Blur处理  
  64.             RenderTexture temp1 = RenderTexture.GetTemporary(source.width >> downSample, source.height >> downSample, 0);  
  65.             RenderTexture temp2 = RenderTexture.GetTemporary(source.width >> downSample, source.height >> downSample, 0);  
  66.   
  67.             //高斯模糊,两次模糊,横向纵向,使用pass0进行高斯模糊  
  68.             _Material.SetVector("_offsets"new Vector4(0, samplerScale, 0, 0));  
  69.             Graphics.Blit(renderTexture, temp1, _Material, 0);  
  70.             _Material.SetVector("_offsets"new Vector4(samplerScale, 0, 0, 0));  
  71.             Graphics.Blit(temp1, temp2, _Material, 0);  
  72.   
  73.             //如果有叠加再进行迭代模糊处理  
  74.             for (int i = 0; i < iteration; i++)  
  75.             {  
  76.                 _Material.SetVector("_offsets"new Vector4(0, samplerScale, 0, 0));  
  77.                 Graphics.Blit(temp2, temp1, _Material, 0);  
  78.                 _Material.SetVector("_offsets"new Vector4(samplerScale, 0, 0, 0));  
  79.                 Graphics.Blit(temp1, temp2, _Material, 0);  
  80.             }  
  81.   
  82.             //叠加效果  
  83.             _Material.SetTexture("_BlurTex", temp1);  
  84.             _Material.SetFloat("_OutlineStrength", outLineStrength);  
  85.             Graphics.Blit(source, destination, _Material, 2);  
  86.   
  87.             RenderTexture.ReleaseTemporary(temp1);  
  88.             RenderTexture.ReleaseTemporary(temp2);  
  89.         }  
  90.         else  
  91.         {  
  92.             Graphics.Blit(source, destination);  
  93.         }  
  94.     }  
  95. }  
shader代码如下,其实就是之前的描边shader,偷了个懒,继续用一下(Pass1没有用):
[csharp] view plain copy
  1. //后处理描边Shader  
  2. //by:puppet_master  
  3. //2017.1.12  
  4.   
  5. Shader "Custom/OutLinePostEffect" {  
  6.   
  7.     Properties{  
  8.         _MainTex("Base (RGB)", 2D) = "white" {}  
  9.         _BlurTex("Blur", 2D) = "white"{}  
  10.     }  
  11.   
  12.     CGINCLUDE  
  13.     #include "UnityCG.cginc"  
  14.       
  15.     //用于剔除中心留下轮廓  
  16.     struct v2f_cull  
  17.     {  
  18.         float4 pos : SV_POSITION;  
  19.         float2 uv : TEXCOORD0;  
  20.     };  
  21.   
  22.     //用于模糊  
  23.     struct v2f_blur  
  24.     {  
  25.         float4 pos : SV_POSITION;  
  26.         float2 uv  : TEXCOORD0;  
  27.         float4 uv01 : TEXCOORD1;  
  28.         float4 uv23 : TEXCOORD2;  
  29.         float4 uv45 : TEXCOORD3;  
  30.     };  
  31.   
  32.     //用于最后叠加  
  33.     struct v2f_add  
  34.     {  
  35.         float4 pos : SV_POSITION;  
  36.         float2 uv  : TEXCOORD0;  
  37.         float2 uv1 : TEXCOORD1;  
  38.     };  
  39.   
  40.     sampler2D _MainTex;  
  41.     float4 _MainTex_TexelSize;  
  42.     sampler2D _BlurTex;  
  43.     float4 _BlurTex_TexelSize;  
  44.     float4 _offsets;  
  45.     float _OutlineStrength;  
  46.   
  47.     //Blur图和原图进行相减获得轮廓  
  48.     v2f_cull vert_cull(appdata_img v)  
  49.     {  
  50.         v2f_cull o;  
  51.         o.pos = mul(UNITY_MATRIX_MVP, v.vertex);  
  52.         o.uv = v.texcoord.xy;  
  53.         //dx中纹理从左上角为初始坐标,需要反向  
  54. #if UNITY_UV_STARTS_AT_TOP  
  55.         if (_MainTex_TexelSize.y < 0)  
  56.             o.uv.y = 1 - o.uv.y;  
  57. #endif    
  58.         return o;  
  59.     }  
  60.   
  61.     fixed4 frag_cull(v2f_cull i) : SV_Target  
  62.     {  
  63.         fixed4 colorMain = tex2D(_MainTex, i.uv);  
  64.         fixed4 colorBlur = tex2D(_BlurTex, i.uv);  
  65.         //最后的颜色是_BlurTex - _MainTex,周围0-0=0,黑色;边框部分为描边颜色-0=描边颜色;中间部分为描边颜色-描边颜色=0。最终输出只有边框  
  66.         //return fixed4((colorBlur - colorMain).rgb, 1);  
  67.         return colorBlur - colorMain;  
  68.     }  
  69.   
  70.     //高斯模糊 vert shader(之前的文章有详细注释,此处也可以用BoxBlur,更省一点)  
  71.     v2f_blur vert_blur(appdata_img v)  
  72.     {  
  73.         v2f_blur o;  
  74.         _offsets *= _MainTex_TexelSize.xyxy;  
  75.         o.pos = mul(UNITY_MATRIX_MVP, v.vertex);  
  76.         o.uv = v.texcoord.xy;  
  77.   
  78.         o.uv01 = v.texcoord.xyxy + _offsets.xyxy * float4(1, 1, -1, -1);  
  79.         o.uv23 = v.texcoord.xyxy + _offsets.xyxy * float4(1, 1, -1, -1) * 2.0;  
  80.         o.uv45 = v.texcoord.xyxy + _offsets.xyxy * float4(1, 1, -1, -1) * 3.0;  
  81.   
  82.         return o;  
  83.     }  
  84.   
  85.     //高斯模糊 pixel shader  
  86.     fixed4 frag_blur(v2f_blur i) : SV_Target  
  87.     {  
  88.         fixed4 color = fixed4(0,0,0,0);  
  89.         color += 0.40 * tex2D(_MainTex, i.uv);  
  90.         color += 0.15 * tex2D(_MainTex, i.uv01.xy);  
  91.         color += 0.15 * tex2D(_MainTex, i.uv01.zw);  
  92.         color += 0.10 * tex2D(_MainTex, i.uv23.xy);  
  93.         color += 0.10 * tex2D(_MainTex, i.uv23.zw);  
  94.         color += 0.05 * tex2D(_MainTex, i.uv45.xy);  
  95.         color += 0.05 * tex2D(_MainTex, i.uv45.zw);  
  96.         return color;  
  97.     }  
  98.   
  99.     //最终叠加 vertex shader  
  100.     v2f_add vert_add(appdata_img v)  
  101.     {  
  102.         v2f_add o;  
  103.         //mvp矩阵变换  
  104.         o.pos = mul(UNITY_MATRIX_MVP, v.vertex);  
  105.         //uv坐标传递  
  106.         o.uv.xy = v.texcoord.xy;  
  107.         o.uv1.xy = o.uv.xy;  
  108. #if UNITY_UV_STARTS_AT_TOP  
  109.         if (_MainTex_TexelSize.y < 0)  
  110.             o.uv.y = 1 - o.uv.y;  
  111. #endif    
  112.         return o;  
  113.     }  
  114.   
  115.     fixed4 frag_add(v2f_add i) : SV_Target  
  116.     {  
  117.         //取原始场景图片进行采样  
  118.         fixed4 ori = tex2D(_MainTex, i.uv1);  
  119.         //取得到的轮廓图片进行采样  
  120.         fixed4 blur = tex2D(_BlurTex, i.uv);  
  121.         //return blur;  
  122.         fixed4 final = ori + blur * _OutlineStrength;  
  123.         return final;  
  124.     }  
  125.   
  126.         ENDCG  
  127.   
  128.     SubShader  
  129.     {  
  130.         //pass 0: 高斯模糊  
  131.         Pass  
  132.         {  
  133.             ZTest Off  
  134.             Cull Off  
  135.             ZWrite Off  
  136.             Fog{ Mode Off }  
  137.   
  138.             CGPROGRAM  
  139.             #pragma vertex vert_blur  
  140.             #pragma fragment frag_blur  
  141.             ENDCG  
  142.         }  
  143.           
  144.         //pass 1: 剔除中心部分   
  145.         Pass  
  146.         {  
  147.             ZTest Off  
  148.             Cull Off  
  149.             ZWrite Off  
  150.             Fog{ Mode Off }  
  151.   
  152.             CGPROGRAM  
  153.             #pragma vertex vert_cull  
  154.             #pragma fragment frag_cull  
  155.             ENDCG  
  156.         }  
  157.   
  158.   
  159.         //pass 2: 最终叠加  
  160.         Pass  
  161.         {  
  162.   
  163.             ZTest Off  
  164.             Cull Off  
  165.             ZWrite Off  
  166.             Fog{ Mode Off }  
  167.   
  168.             CGPROGRAM  
  169.             #pragma vertex vert_add  
  170.             #pragma fragment frag_add  
  171.             ENDCG  
  172.         }  
  173.     }  
  174. }  
然后人物本身的shader我们换成边缘光的shader(可以参考之前的文章),效果如下:
其实上面的做法稍微感觉有点费,当然,我们也可以按照CommondBuffer假景深效果的做法,直接通过CommandBuffer把人物渲染顺序直接调整到最后渲染,然后在人物身上用一个边缘光的效果,虽然可以达到在人模不被遮挡地渲染,不过效果可能不会有模糊的效果好。模糊外扩的效果用常规的shader一般是很难做出来的,还是全屏的Blur比较容易出这种效果。
 

遮挡半透

 
遮挡半透是游戏中非常常用的处理遮挡的手段。开头提到过的《黑魂2》,《Ori》都是用了这个效果,这俩游戏也都让我差点摔手柄.....半年之前开始玩的《Ori》,后来直接弃坑了,前一阵子才刚刚通关《Ori》,死了1700多次,不过游戏是真的好,虽然这辈子也不想再玩第二次了。额,一不小心又扯远了,而且不小心透露了最近断更的主要原因。下面继续看遮挡半透。
遮挡半透的原理其实比较简单,就是我们需要做一下从摄像机到人之间的射线查询,如果查询到了物体,那么就说明这个物体是一个遮挡物,然后我们就可以把它用一个半透的shader进行渲染,当查询失效之后,我们再将其恢复成原始的shader,基本的遮挡半透就完成了。不过这样会比较突兀,所以一般在开始半透和结束半透的时候,都是有一个渐变的过程的。我们先来把这一套机制实现一下,因为这个毕竟比较简单,属于逻辑层级的。真正复杂的东东还是半透渲染本身带来的一系列问题。不多说,上代码:
[csharp] view plain copy
  1. /******************************************************************** 
  2.  FileName: TransparentControl.cs 
  3.  Description: 遮挡半透查询控制器,挂于摄像机 
  4.  Created: 2017/07/23 
  5.  history: 23:7:2017 12:45 by puppet_master 
  6. *********************************************************************/  
  7. using System.Collections;  
  8. using System.Collections.Generic;  
  9. using UnityEngine;  
  10. using System.Linq;  
  11.   
  12. public class TransparentControl : MonoBehaviour {  
  13.   
  14.     public class TransparentParam  
  15.     {  
  16.         public Material[] materials = null;  
  17.         public Material[] sharedMats = null;  
  18.         public float currentFadeTime = 0;  
  19.         public bool isTransparent = true;  
  20.     }  
  21.   
  22.     public Transform targetObject = null;   //目标对象  
  23.     public float height = 3.0f;             //目标对象Y方向偏移  
  24.     public float destTransparent = 0.2f;    //遮挡半透的最终半透强度,  
  25.     public float fadeInTime = 1.0f;         //开始遮挡半透时渐变时间  
  26.     private int transparentLayer;           //需要遮挡半透的层级  
  27.     private Dictionary<Renderer, TransparentParam> transparentDic = new Dictionary<Renderer, TransparentParam>();  
  28.     private List<Renderer> clearList = new List<Renderer>();  
  29.   
  30.     void Start ()  
  31.     {  
  32.         transparentLayer = 1 << LayerMask.NameToLayer("OcclusionTran");  
  33.     }  
  34.       
  35.     void Update ()  
  36.     {  
  37.         if (targetObject == null)  
  38.             return;  
  39.         UpdateTransparentObject();  
  40.         UpdateRayCastHit();  
  41.         RemoveUnuseTransparent();  
  42.     }  
  43.   
  44.     public void UpdateTransparentObject()  
  45.     {  
  46.         var var = transparentDic.GetEnumerator();  
  47.         while (var.MoveNext())  
  48.         {  
  49.             TransparentParam param = var.Current.Value;  
  50.             param.isTransparent = false;  
  51.             foreach (var mat in param.materials)  
  52.             {  
  53.                 Color col = mat.GetColor("_Color");  
  54.                 param.currentFadeTime += Time.deltaTime;  
  55.                 float t = param.currentFadeTime / fadeInTime;  
  56.                 col.a = Mathf.Lerp(1, destTransparent, t);  
  57.                 mat.SetColor("_Color", col);  
  58.             }  
  59.         }  
  60.     }  
  61.   
  62.     public void UpdateRayCastHit()  
  63.     {  
  64.         RaycastHit[] rayHits = null;  
  65.         //视线方向为从自身(相机)指向目标位置  
  66.         Vector3 targetPos = targetObject.position + new Vector3(0, height, 0);  
  67.         Vector3 viewDir = (targetPos - transform.position).normalized;  
  68.         Vector3 oriPos = transform.position;  
  69.         float distance = Vector3.Distance(oriPos, targetPos);  
  70.         Ray ray = new Ray(oriPos, viewDir);  
  71.         rayHits = Physics.RaycastAll(ray, distance, transparentLayer);  
  72.         //直接在Scene画一条线,方便观察射线  
  73.         Debug.DrawLine(oriPos, targetPos, Color.red);  
  74.         foreach (var hit in rayHits)  
  75.         {  
  76.             Renderer[] renderers = hit.collider.GetComponentsInChildren<Renderer>();  
  77.             foreach (Renderer r in renderers)  
  78.             {  
  79.                 AddTransparent(r);  
  80.             }  
  81.         }  
  82.     }  
  83.   
  84.     public void RemoveUnuseTransparent()  
  85.     {  
  86.         clearList.Clear();  
  87.         var var = transparentDic.GetEnumerator();  
  88.         while(var.MoveNext())  
  89.         {  
  90.             if (var.Current.Value.isTransparent == false)  
  91.             {  
  92.                 //用完后材质实例不会销毁,可以被unloadunuseasset销毁或切场景销毁。  
  93.                 var.Current.Key.materials = var.Current.Value.sharedMats;  
  94.                 clearList.Add(var.Current.Key);  
  95.             }  
  96.         }  
  97.         foreach(var v in clearList)  
  98.             transparentDic.Remove(v);  
  99.     }  
  100.   
  101.     void AddTransparent(Renderer renderer)  
  102.     {  
  103.         TransparentParam param = null;  
  104.         transparentDic.TryGetValue(renderer, out param);  
  105.         if (param == null)  
  106.         {  
  107.             param = new TransparentParam();  
  108.             transparentDic.Add(renderer, param);  
  109.             //此处顺序不能反,调用material会产生材质实例。  
  110.             param.sharedMats = renderer.sharedMaterials;  
  111.             param.materials = renderer.materials;  
  112.             foreach(var v in param.materials)  
  113.             {  
  114.                 v.shader = Shader.Find("ApcShader/OcclusionTransparent");  
  115.             }  
  116.         }  
  117.         param.isTransparent = true;  
  118.     }  
  119. }  
我们先用Unity自带的半透的shader试一下,这次我们直接用一个surface shader:
[csharp] view plain copy
  1. Shader "ApcShader/OcclusionTransparent" {  
  2.     Properties {  
  3.         _Color ("Main Color", Color) = (1,1,1,1)  
  4.         _MainTex ("Base (RGB)", 2D) = "white" {}  
  5.     }  
  6.     SubShader {  
  7.         Tags { "RenderType"="Transparent" "Queue" = "Transparent"}  
  8.           
  9.         ZWrite Off  
  10.   
  11.         CGPROGRAM  
  12.         #pragma surface surf Lambert alpha  
  13.   
  14.         sampler2D _MainTex;  
  15.         fixed4 _Color;  
  16.   
  17.         struct Input {  
  18.             float2 uv_MainTex;  
  19.         };  
  20.   
  21.         void surf (Input IN, inout SurfaceOutput o) {  
  22.             fixed4 c = tex2D(_MainTex, IN.uv_MainTex) * _Color;  
  23.             o.Albedo = c.rgb;  
  24.             o.Alpha = c.a;  
  25.         }  
  26.         ENDCG  
  27.     }   
  28.     FallBack "VertexLit"  
  29. }  
然后,我们在场景中尝试一下这个效果。首先,需要把需要遮挡半透的物体添加碰撞体组件,这里我们直接用BoxCollider,毕竟碰撞体越简单,性能越好。然后在相机上挂上TransparentController脚本,当相机和人物中间出现了遮挡物,遮挡物就会自动替换成半透shader。效果如下:
从上图中,我们可以看到,遮挡的栅栏变成了半透的效果。不过,这个半透看起来的效果有点奇怪,我们会看到这个物体内部的一些正常情况下看不见的东西,其实这种效果并不是我想要的,我们想要的一般就是正常与不透明渲染一样,只是能看到离我们最近的一个面,其他的部分都看不到。我们一般的半透都是用于特效,玻璃等效果,这种东西一般都是一个薄片,这种情况不是很明显,但是栅栏这种比较复杂的物体,自身存在前后遮挡的关系,这种效果就暴露得比较明显。
为什么会出现这种情况?我们还是要来复习一下渲染的基本知识。我们为了保证渲染的正确性,一般是有两种方法保证渲染的正确性。一种是Z Buffer算法,也是我们现在渲染最常用的一种。比如我们渲染一个物体的一个像素,首先要进行Z Test(深度测试),如果深度测试不通过,那么它本身就没有必要在这个像素进行渲染了。而Z Write(深度写入)则是在上面的深度测试通过之后,更新该像素深度值的一个操作。半透渲染深度测试也是有效的,比如一个半透物体如果在一个不透明的物体之后,深度测试失败,那么就没有必要再进行混合操作了,但是半透渲染没有办法开启深度写入,因为半透需要Blend,需要原缓冲区的颜色与当前fragment的颜色进行混合,如果前后两个物体同时开启了深度写入,那么前面那个就会挡住后面那个。不过这种情况在Unity里面我们并没有看到,其实是因为Unity对半透明物体采用了另一种算法,也就是画家算法,所谓画家算法就是先画后面的,再画前面的。Unity会对同一个渲染队列的半透物体进行排序,然后再按照远近顺序进行渲染。这样基本就可以保证Blend的正确性。
虽然说一般我们不会开启半透物体的深度写入,但是这样就会出现上图的问题。比如我们想渲染一个人,不透明渲染的话,从左边看,我们只会看到人的左手边,但是如果用了半透渲染,我们就会在看到人的左手的同时看到右手,这肯定效果很奇怪。有一种解决办法,就是我们可以进行一次Z PrePass操作,用两个pass渲染遮挡物体,先用一个不写入颜色,只写入深度的pass渲染一遍,这样这个位置就已经写入了深度;第二个pass进行正常的渲染,离我们近的面深度测试成功,会正常渲染,但是远离我们的面深度测试失败,就不会渲染了。把上面的shader加工一下,增加一个Prepass:
 
[csharp] view plain copy
  1. //增加prepass的半透渲染  
  2. //by:puppet_master  
  3. //2017.7.23  
  4. Shader "ApcShader/OcclusionTransparent" {  
  5.     Properties {  
  6.         _Color ("Main Color", Color) = (1,1,1,1)  
  7.         _MainTex ("Base (RGB)", 2D) = "white" {}  
  8.     }  
  9.     SubShader {  
  10.         Tags { "RenderType"="Transparent" "Queue" = "Transparent-1"}  
  11.           
  12.         Pass  
  13.         {  
  14.             ZWrite On   //开启深度写入  
  15.             ColorMask 0 //不写颜色  
  16.         }     
  17.           
  18.         ZWrite Off  
  19.         CGPROGRAM  
  20.         #pragma surface surf Lambert alpha  
  21.   
  22.         sampler2D _MainTex;  
  23.         fixed4 _Color;  
  24.   
  25.         struct Input {  
  26.             float2 uv_MainTex;  
  27.         };  
  28.   
  29.         void surf (Input IN, inout SurfaceOutput o) {  
  30.             fixed4 c = tex2D(_MainTex, IN.uv_MainTex) * _Color;  
  31.             o.Albedo = c.rgb;  
  32.             o.Alpha = c.a;  
  33.         }  
  34.         ENDCG  
  35.     }   
  36.     FallBack "VertexLit"  
  37. }  
下面来一张图来对比一下使用了 Prepass和正常渲染的半透效果:

左边使用了Z Prepass,我们只能看到离我们最近的面,但是右侧只用一个pass渲染的时候,我们可以很明显地看到台子的支柱等里面的内容。下面来一张动图看一下遮挡半透的效果,增加了开始半透时的渐变效果(结束的时候偷个懒,就先不加啦):


遮挡溶解


遮挡溶解效果,个人感觉是这四种效果中最好玩的效果,当然也是最复杂最费的效果。这个效果我最早是在《神界》中看到,当时就被这个效果吸引住了,不过一直没想通是怎么做出来的,一直想用NSight抓,然而家里的电脑还是个坑爹的A卡,AMD那个神奇的工具从来没抓成功过(包括自己写的小图形程序也抓不到.....),唉,不吐槽了,还是得努力搬砖攒钱换块N卡。就在我一筹莫展的时候,看到了腾讯GAD上的两篇翻译文章:Trifox遮挡处理(上)Trifox遮挡处理(下),简直如醍醐灌顶,英文原文在这里,再次膜拜一下大神。
遮挡溶解,这种效果的处理方法与之前的又大不相同,并不是一直进行射线检测,而是把可能需要这种溶解效果的对象直接设置为溶解shader,这个shader主要是一种溶解的效果,但与之前的普通溶解不同,我们需要让物体只在我们视野范围内一定距离才进行溶解。这就需要引入一个新的空间,在计算fragment阶段时,我们需要知道这个像素在我们屏幕空间的位置,在研究GrabPass的时候,我们使用过一个函数-ComputeGrabScreenPos,这个函数就可以通过传入mvp变化后的顶点,计算出该顶点对于屏幕空间的位置。不过要真正获得这个顶点的位置,我们计算的时候需要除以最后一个分量,比如上面的栅栏,我们用这样一个函数直接输出它每个像素对于屏幕空间的位置值:
[csharp] view plain copy
  1. //vertex阶段  
  2. o.pos = mul(UNITY_MATRIX_MVP, v.vertex);  
  3. o.screenPos = ComputeGrabScreenPos(o.pos);  
  4. //fragment阶段  
  5. float screenSpacePos = i.screenPos.y / i.screenPos.w;  
  6. return fixed4(screenSpacePos, screenSpacePos, screenSpacePos, 1);  
比如我们把屏幕空间Y方向的位置输出出来,效果如下:
既然我们可以得到这个物体每个像素点位于屏幕的位置,我们就可以计算出这个顶点距离中心点的距离,代码如下:
[csharp] view plain copy
  1. float2 screenPos = i.screenPos.xy / i.screenPos.w;  
  2. float2 dir = float2(0.5, 0.5) - screenPos;  
  3. float distance = sqrt(dir.x * dir.x + dir.y * dir.y);  
  4. return fixed4(distance, distance, distance, 1);  
吼吼,这下,只要在屏幕中心的,就被我们挖出了一个洞。在屏幕水波纹效果中我们进行全屏后处理的时候有过类似的做法。

然后给一个阈值,大于这个阈值的正常渲染,小于这个阈值的进行溶解或者不显示,溶解的shader如下:
[csharp] view plain copy
  1. //遮挡溶解效果  
  2. //by:puppet_master  
  3. //2017.7.23  
  4.   
  5. Shader "ApcShader/OcclusionDissolve"  
  6. {  
  7.     Properties{  
  8.         _Diffuse("Diffuse", Color) = (1,1,1,1)  
  9.         _DissolveColorA("Dissolve Color A", Color) = (0,0,0,0)  
  10.         _DissolveColorB("Dissolve Color B", Color) = (1,1,1,1)  
  11.         _MainTex("Base 2D", 2D) = "white"{}  
  12.         _DissolveMap("DissolveMap", 2D) = "white"{}  
  13.         _DissolveThreshold("DissolveThreshold", Range(0,2)) = 0  
  14.         _ColorFactorA("ColorFactorA", Range(0,1)) = 0.7  
  15.         _ColorFactorB("ColorFactorB", Range(0,1)) = 0.8  
  16.     }  
  17.       
  18.     CGINCLUDE  
  19.     #include "Lighting.cginc"  
  20.     uniform fixed4 _Diffuse;  
  21.     uniform fixed4 _DissolveColorA;  
  22.     uniform fixed4 _DissolveColorB;  
  23.     uniform sampler2D _MainTex;  
  24.     uniform float4 _MainTex_ST;  
  25.     uniform sampler2D _DissolveMap;  
  26.     uniform float _DissolveThreshold;  
  27.     uniform float _ColorFactorA;  
  28.     uniform float _ColorFactorB;  
  29.       
  30.     struct v2f  
  31.     {  
  32.         float4 pos : SV_POSITION;  
  33.         float3 worldNormal : TEXCOORD0;  
  34.         float2 uv : TEXCOORD1;  
  35.         float4 screenPos : TEXCOORD2;  
  36.     };  
  37.       
  38.     v2f vert(appdata_base v)  
  39.     {  
  40.         v2f o;  
  41.         o.pos = mul(UNITY_MATRIX_MVP, v.vertex);  
  42.         o.uv = TRANSFORM_TEX(v.texcoord, _MainTex);  
  43.         o.worldNormal = mul(v.normal, (float3x3)unity_WorldToObject);  
  44.         o.pos = mul(UNITY_MATRIX_MVP, v.vertex);  
  45.         //计算屏幕坐标  
  46.         o.screenPos = ComputeGrabScreenPos(o.pos);  
  47.         return o;  
  48.     }  
  49.       
  50.     fixed4 frag(v2f i) : SV_Target  
  51.     {  
  52.         float2 screenPos = i.screenPos.xy / i.screenPos.w;  
  53.         //计算距离中心点距离  
  54.         float2 dir = float2(0.5, 0.5) - screenPos;  
  55.         float distance = sqrt(dir.x * dir.x + dir.y * dir.y);  
  56.         //距离中心点近的才进行溶解处理  
  57.         float disolveFactor = (0.5 - distance) * _DissolveThreshold;  
  58.         //采样Dissolve Map  
  59.         fixed4 dissolveValue = tex2D(_DissolveMap, i.uv);  
  60.         //小于阈值的部分直接discard  
  61.         if (dissolveValue.r < disolveFactor)  
  62.         {  
  63.             discard;  
  64.         }  
  65.         //Diffuse + Ambient光照计算  
  66.         fixed3 worldNormal = normalize(i.worldNormal);  
  67.         fixed3 worldLightDir = normalize(_WorldSpaceLightPos0.xyz);  
  68.         fixed3 lambert = saturate(dot(worldNormal, worldLightDir));  
  69.         fixed3 albedo = lambert * _Diffuse.xyz * _LightColor0.xyz + UNITY_LIGHTMODEL_AMBIENT.xyz;  
  70.         fixed3 color = tex2D(_MainTex, i.uv).rgb * albedo;  
  71.         //这里为了比较方便,直接用color和最终的边缘lerp了  
  72.         float lerpValue = disolveFactor / dissolveValue.r;  
  73.         if (lerpValue > _ColorFactorA)  
  74.         {  
  75.             if (lerpValue > _ColorFactorB)  
  76.                 return _DissolveColorB;  
  77.             return _DissolveColorA;  
  78.         }  
  79.         return fixed4(color, 1);  
  80.     }  
  81.     ENDCG  
  82.       
  83.     SubShader  
  84.     {  
  85.         Tags{ "RenderType" = "Opaque" }  
  86.         Pass  
  87.         {  
  88.             CGPROGRAM  
  89.             #pragma vertex vert  
  90.             #pragma fragment frag     
  91.             ENDCG  
  92.         }  
  93.     }  
  94.     FallBack "Diffuse"  
  95. }  
给一张噪声图,调整一个比较酷炫的颜色,然后我们就可以看到之前普通的溶解效果会随着我们视线的位置溶解掉我们看到的东西:

哇塞,有一种鼬神天照的赶脚,看哪哪溶解。要是什么时候Get到这样的神技就好了。不过现在这种效果确实有些太猛了点,视线之内寸草不生,貌似不是我们想要的效果,毕竟我们想解决的只是挡住主角的那一部分。所以,我们需要给一个距离限制,当这个像素点距离相机在这个距离限制之内,就进行溶解,否则不进行溶解。其实这个距离刚好就可以给成我们相机到主角之间的距离,这样,只要人物经过哪里,人物和相机之间的内容就会进行溶解。我们给上面的shader加工一下,增加一个距离的限制:
[csharp] view plain copy
  1. //遮挡溶解效果  
  2. //by:puppet_master  
  3. //2017.7.26  
  4.   
  5. Shader "ApcShader/OcclusionDissolve"  
  6. {  
  7.     Properties{  
  8.         _Diffuse("Diffuse", Color) = (1,1,1,1)  
  9.         _DissolveColorA("Dissolve Color A", Color) = (0,1,1,0)  
  10.         _DissolveColorB("Dissolve Color B", Color) = (0.3,0.3,0.3,1)  
  11.         _MainTex("Base 2D", 2D) = "white"{}  
  12.         _DissolveMap("DissolveMap", 2D) = "white"{}  
  13.         _DissolveThreshold("DissolveThreshold", Range(0,2)) = 2  
  14.         _ColorFactorA("ColorFactorA", Range(0,1)) = 0.7  
  15.         _ColorFactorB("ColorFactorB", Range(0,1)) = 0.8  
  16.         _DissolveDistance("DissolveDistance", Range(0, 20)) = 14  
  17.         _DissolveDistanceFactor("DissolveDistanceFactor", Range(0,3)) = 3  
  18.     }  
  19.       
  20.     CGINCLUDE  
  21.     #include "Lighting.cginc"  
  22.     uniform fixed4 _Diffuse;  
  23.     uniform fixed4 _DissolveColorA;  
  24.     uniform fixed4 _DissolveColorB;  
  25.     uniform sampler2D _MainTex;  
  26.     uniform float4 _MainTex_ST;  
  27.     uniform sampler2D _DissolveMap;  
  28.     uniform float _DissolveThreshold;  
  29.     uniform float _ColorFactorA;  
  30.     uniform float _ColorFactorB;  
  31.     uniform float _DissolveDistance;  
  32.     uniform float _DissolveDistanceFactor;  
  33.       
  34.     struct v2f  
  35.     {  
  36.         float4 pos : SV_POSITION;  
  37.         float3 worldNormal : TEXCOORD0;  
  38.         float2 uv : TEXCOORD1;  
  39.         float4 screenPos : TEXCOORD2;  
  40.         float3 viewDir : TEXCOORD3;  
  41.     };  
  42.       
  43.     v2f vert(appdata_base v)  
  44.     {  
  45.         v2f o;  
  46.         o.pos = mul(UNITY_MATRIX_MVP, v.vertex);  
  47.         o.uv = TRANSFORM_TEX(v.texcoord, _MainTex);  
  48.         o.worldNormal = mul(v.normal, (float3x3)unity_WorldToObject);  
  49.         o.pos = mul(UNITY_MATRIX_MVP, v.vertex);  
  50.         o.viewDir = ObjSpaceViewDir(v.vertex);  
  51.         //计算屏幕坐标  
  52.         o.screenPos = ComputeGrabScreenPos(o.pos);  
  53.         return o;  
  54.     }  
  55.       
  56.     fixed4 frag(v2f i) : SV_Target  
  57.     {  
  58.         float2 screenPos = i.screenPos.xy / i.screenPos.w;  
  59.         //计算距离中心点距离作为一个控制系数  
  60.         float2 dir = float2(0.5, 0.5) - screenPos;  
  61.         float screenSpaceDistance = 0.5 - sqrt(dir.x * dir.x + dir.y * dir.y);  
  62.         //计算一下像素点到相机距离作为另一个控制系数  
  63.         float viewDistance =  max(0,(_DissolveDistance - length(i.viewDir)) / _DissolveDistance) * _DissolveDistanceFactor;  
  64.         //用两个控制系数作为最终溶解的系数  
  65.         float disolveFactor = viewDistance * screenSpaceDistance * _DissolveThreshold;  
  66.         //采样Dissolve Map  
  67.         fixed4 dissolveValue = tex2D(_DissolveMap, i.uv);  
  68.         //小于阈值的部分直接discard  
  69.         if (dissolveValue.r < disolveFactor)  
  70.         {  
  71.             discard;  
  72.         }  
  73.         //Diffuse + Ambient光照计算  
  74.         fixed3 worldNormal = normalize(i.worldNormal);  
  75.         fixed3 worldLightDir = normalize(_WorldSpaceLightPos0.xyz);  
  76.         fixed3 lambert = saturate(dot(worldNormal, worldLightDir));  
  77.         fixed3 albedo = lambert * _Diffuse.xyz * _LightColor0.xyz + UNITY_LIGHTMODEL_AMBIENT.xyz;  
  78.         fixed3 color = tex2D(_MainTex, i.uv).rgb * albedo;  
  79.         //这里为了比较方便,直接用color和最终的边缘lerp了  
  80.         float lerpValue = disolveFactor / dissolveValue.r;  
  81.         if (lerpValue > _ColorFactorA)  
  82.         {  
  83.             if (lerpValue > _ColorFactorB)  
  84.                 return _DissolveColorB;  
  85.             return _DissolveColorA;  
  86.         }  
  87.         return fixed4(color, 1);  
  88.     }  
  89.     ENDCG  
  90.       
  91.     SubShader  
  92.     {  
  93.         Tags{ "RenderType" = "Opaque" }  
  94.         Pass  
  95.         {  
  96.             CGPROGRAM  
  97.             #pragma vertex vert  
  98.             #pragma fragment frag     
  99.             ENDCG  
  100.         }  
  101.     }  
  102.     FallBack "Diffuse"  
  103. }  
效果如下面动态图所示,只有在距离相机距离比较近的内容才会被溶解掉:

最终效果如下图所示,人物走过的部分可能会遮挡人物的物体就都被溶解掉了:


当然,这个遮挡溶解的效果与原文的效果还是有一定差距的,主要是溶解我们使用的还是噪声图的溶解,没有使用程序噪声,采样方法也不一样,进一步优化打算等之后的文章再写啦,这篇写得好累....

阅读更多
换一批

没有更多推荐了,返回首页