多个ROS包使用不同Opencv版本冲突解决

lucky li

已于 2024-03-29 19:07:25 修改

阅读量1k

点赞数 15

分类专栏： ROS 文章标签： opencv 人工智能计算机视觉

于 2024-03-12 17:06:01 首次发布

本文链接：https://blog.csdn.net/weixin_41965898/article/details/136655664

版权

ROS 专栏收录该内容

7 篇文章 0 订阅

订阅专栏

多个ROS包使用不同Opencv版本冲突一般发生在opencv3和opencv4之间，一劳永逸的解决就是修改代码将3升级到4。

本文提供的方式是不修改代码，隔离opencv环境，使多个opencv版本共存，且被不同ros包编译使用时隔离。

1 源码编译opencv且install到本地。

mkdir -p /home/lucky/Lib/opencv3.4
mv opencv_contrib-3.4.5.tar.gz /home/lucky/Lib/opencv3.4
mv opencv-3.4.5.tar.gz /home/lucky/Lib/opencv3.4
cd /home/lucky/Lib/opencv3.4
tar -xvf opencv_contrib-3.4.5.tar.gz 
tar -xvf opencv-3.4.5.tar.gz 
mv opencv-3.4.5 opencv
mv opencv_contrib-3.4.5 opencv_contrib
cd opencv
mkdir build && cd build
cmake -D CMAKE_BUILD_TYPE=RELEASE -D CMAKE_INSTALL_PREFIX=../../opencv/install -D CMAKE_BUILD_TYPE=RELEASE  -D WITH_OPENGL=ON  -D OPENCV_EXTRA_MODULES_PATH=../../opencv_contrib/modules ..
make -j8
make install

注意：CMAKE_INSTALL_PREFIX=../../opencv/install 已经被指定为/home/lucky/opencv3.4/opencv/install目录。因此make install不会安装到系统/usr 目录中，也不需要sudo

2 cv_bridge带来的冲突

我们通常apt安装ros时，会安装了ros-noetic-cv-bridge，这个包被rviz等使用。注意ros-noetic-cv-bridge通常会依赖系统提供的libopencv-dev==4.2，以ubuntu20为例，系统会有一套依赖库：

ros-noetic-desktop -> ros-noetic-cv-bridge -> opencv4.2

假如你的ros包依赖cv-bridge同时依赖opencv3.4，如果你使用ros提供的ros-noetic-cv-bridge（opencv4.2）和自己编译的opencv3.4，那么程序中会有两种libopencv，程序运行时会崩溃，有时候不崩溃但是程序卡住或者数据出错。

例如：

lucky@lucky:~/ws_vins/devel/lib$ ldd feature_tracker/feature_tracker | grep libopencv_core
libopencv_core.so.4.2 => /home/lucky/Lib/opencv4.2/opencv/install/lib/libopencv_core.so.4.2 (0x00007f774bbeb000)
libopencv_core.so.3.4 => /home/lucky/Lib/opencv3.4/opencv/install/lib/libopencv_core.so.3.4 (0x00007f520686c000)

解决：使用自己本地install的opencv3.4 编译cv_bridge，并把编译好的cv_bridge 安装在本地。

mkdir -p ~/Lib
下载 https://github.com/ros-perception/vision_opencv/archive/refs/tags/1.13.1.zip
mv vision_opencv-1.13.1.zip ~/Lib
unzip vision_opencv-1.13.1.zip
cd ~/Lib/vision_opencv-1.13.1/cv_bridge
gedit CMakeLists.txt 替换成如下
```
cmake_minimum_required(VERSION 3.0.2)
project(cv_bridge)

find_package(catkin REQUIRED COMPONENTS rosconsole sensor_msgs)

if(NOT ANDROID)
  find_package(PythonLibs)

  if(PYTHONLIBS_VERSION_STRING VERSION_LESS "3.8")
    # Debian Buster
    find_package(Boost REQUIRED python37)
  else()
    # Ubuntu Focal
    find_package(Boost REQUIRED python)
  endif()
else()
find_package(Boost REQUIRED)
endif()

set(OpenCV_DIR "/home/lucky/Lib/opencv3.4/opencv/install/share/OpenCV")
# set(OpenCV_DIR "/home/lucky/Lib/opencv4.5/opencv/install/lib/cmake/opencv4/")
find_package(OpenCV 3.4.5 REQUIRED
  COMPONENTS
    opencv_core
    opencv_imgproc
    opencv_imgcodecs
  CONFIG
)

catkin_package(
  INCLUDE_DIRS include
  LIBRARIES ${PROJECT_NAME}
  CATKIN_DEPENDS rosconsole sensor_msgs
  DEPENDS OpenCV
  CFG_EXTRAS cv_bridge-extras.cmake
)

catkin_python_setup()

include_directories(include ${Boost_INCLUDE_DIRS} ${OpenCV_INCLUDE_DIRS} ${catkin_INCLUDE_DIRS})
link_directories(${Boost_LIBRARY_DIRS})

if(NOT ANDROID)
add_subdirectory(python)
endif()
add_subdirectory(src)
if(CATKIN_ENABLE_TESTING)
  add_subdirectory(test)
endif()

# install the include folder
install(
  DIRECTORY include/${PROJECT_NAME}/
  DESTINATION ${CATKIN_PACKAGE_INCLUDE_DESTINATION}
)

# Create uninstall target
configure_file(
    "${CMAKE_CURRENT_SOURCE_DIR}/cmake/uninstall.cmake.in"
    "${CMAKE_CURRENT_BINARY_DIR}/uninstall.cmake"
    IMMEDIATE @ONLY
)

add_custom_target(uninstall
    COMMAND ${CMAKE_COMMAND} -P ${CMAKE_CURRENT_BINARY_DIR}/uninstall.cmake
)
```

gedit cmake/uninstall.cmake.in 拷贝如下内容:（可选，支持uninstall）
```
if(NOT EXISTS "${CMAKE_BINARY_DIR}/install_manifest.txt")
    message(FATAL_ERROR "Cannot find install manifest: ${CMAKE_BINARY_DIR}/install_manifest.txt")
endif()

file(READ "${CMAKE_BINARY_DIR}/install_manifest.txt" files)
string(REGEX REPLACE "\n" ";" files "${files}")

foreach(file ${files})
    message(STATUS "Uninstalling file: ${file}")
    if(EXISTS "${file}")
        execute_process(
            COMMAND ${CMAKE_COMMAND} -E remove "${file}"
            RESULT_VARIABLE result
        )
        if(NOT ${result} EQUAL 0)
            message(FATAL_ERROR "Failed to uninstall: ${file}")
        endif()
    else()
        message(WARNING "File not found: ${file}")
    endif()
endforeach()
```

mkdir build_with_cv3.4
cd build_with_cv3.4
cmake -DCMAKE_INSTALL_PREFIX=../install_with_cv3.4 ..
make -j8
export LD_LIBRARY_PATH=/home/lucky/Lib/opencv3.4/opencv/install/lib:$LD_LIBRARY_PATH; make install

注意： -DCMAKE_INSTALL_PREFIX=/home/lucky/Lib/vision_opencv-1.13.1/cv_bridge/install，指定为本地安装目录；

opencv3和4的cmake配置文件的DIR不同：set(OpenCV_DIR "/home/lucky/Lib/opencv3.4/opencv/install/share/OpenCV")与set(OpenCV_DIR "/home/lucky/Lib/opencv4.5/opencv/install/lib/cmake/opencv4/")

3 ros包中CMakeLists.txt的修改

以vins_mono中的feature_tracker程序为例，修改~/ws_vins/src/VINS-Mono/feature_tracker/CMakeLists.txt

3.1 opencv的指定

**********
find_package(OpenCV REQUIRED)
**********
改为
**********
set(OpenCV_DIR "/home/lucky/Lib/opencv3.4/opencv/install/share/OpenCV")
find_package(OpenCV 3.4.5 REQUIRED)
**********

3.2 cv_bridge的指定

**********
find_package(catkin REQUIRED COMPONENTS
    roscpp
    std_msgs
    sensor_msgs
    camera_model
    cv_bridge
    )

**********
删除ros中的cv_bridge的依赖,改为：
**********
find_package(catkin REQUIRED COMPONENTS
    roscpp
    std_msgs
    sensor_msgs
    camera_model
    )
**********

指定源码编译的cv_bridge：
**********
set(cv_bridge_DIR "/home/lucky/Lib/vision_opencv-1.13.1/cv_bridge/install_with_cv3.4/share/cv_bridge/cmake")
find_package(cv_bridge 1.13.1 REQUIRED NO_DEFAULT_PATH)
set(OpenCV_DIR "/home/lucky/Lib/opencv3.4/opencv/install/share/OpenCV")
find_package(OpenCV 3.4.5 REQUIRED NO_DEFAULT_PATH)
**********

有时候CMakeLists，按上面修改后虽然可以找到/home/lucky/Lib/vision_opencv-1.13.1/cv_bridge/install/lib/libcv_bridge.so，但总是优先使用了/opt/ros/noetic/lib/libcv_bridge.so，可能跟系统环境有关，可以find_package(cv_bridge 1.13.1 REQUIRED NO_DEFAULT_PATH)

3.3 target_link_libraries指定

**********
target_link_libraries(feature_tracker ${catkin_LIBRARIES} ${OpenCV_LIBS})
**********
改为：
**********
target_link_libraries(feature_tracker ${cv_bridge_LIBRARIES} ${catkin_LIBRARIES} ${OpenCV_LIBS})
**********

3.4 catkin_make

export LD_LIBRARY_PATH=/home/lucky/Lib/opencv3.4/opencv/install/lib:$LD_LIBRARY_PATH
export LD_LIBRARY_PATH=/home/lucky/Lib/vision_opencv-1.13.1/cv_bridge/install/lib:$LD_LIBRARY_PATH
catkin_make

LD_LIBRARY_PATH 中有多个版本的opencv和cv_bridge可能影响其他程序，通过版本号和屏蔽默认（NO_DEFAULT_PATH)的版本两种方式是否生效取决于cv_bridgeConfig.cmake文件是否严格检查。最好不要把export LD_LIBRARY_PATH写入bashrc

4 总结

编译不同版本opencv在本地目录，可以做到多种opencv版本隔离，该方法不需要卸载系统安装的 ros-noetic-cv-bridge -> opencv4.2，不影响rviz或其他ros程序等依赖cv_bridge的使用。

注意：

1 -DCMAKE_INSTALL_PREFIX目录指定为本地

2 不要忽略ros安装的cv_bridge对程序的影响，通常系统安装的cv_bridge依赖的opencv会和程序中依赖的opencv版本不同。

3 自己的ros程序只需要修改CMakeLists.txt，不需要修改源码，本文以vins中的feature_tracker为例，别忘记vins中的其他节点程序的CMakeLists.txt也要修改。

4 多多使用ldd 检查编译后的程序的依赖关系。比如：

ldd ~/Lib/vision_opencv-noetic/cv_bridge/install/lib/libcv_bridge.so | grep cv 的结果中不可以有libopencv_core.so.4.2或其他版本或者not found
ldd ~/ws_vins/devel/lib/feature_tracker/feature_tracker | grep cv 的结果中不可以有libopencv_core.so.4.2或其他版本或者not found，也不可以libcv_bridge.so => /opt/ros/noetic/lib/libcv_bridge.so，要指定为libcv_bridge.so => /home/lucky/Lib/vision_opencv-1.13.1/cv_bridge/install/lib/libcv_bridge.so

lucky li

关注

15
点赞
踩
8

收藏

觉得还不错? 一键收藏
1
评论
多个ROS包使用不同Opencv版本冲突解决

多个ROS包使用不同Opencv版本冲突一般发生在opencv3和opencv4之间，一劳永逸的解决就是修改代码将3升级到4。本文提供的方式是不修改代码，隔离opencv环境，使多个opencv版本共存，且被不同ros包编译使用时隔离。
复制链接

扫一扫